Name	json-glib
Description	JSON library built on GLib
Version	1.10.8-1
Package Base	json-glib
Homepage	https://gnome.pages.gitlab.gnome.org/json-glib/
Maintainers	['Jan Alexander Steffens (heftig) <heftig@archlinux.org>']
Contributors	['Ionut Biru <ibiru@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/json-glib
Sources	['git+https://gitlab.gnome.org/GNOME/json-glib.git?signed#tag=1.10.8']
Dependencies	['glib2', 'glibc', 'libgio-2.0.so', 'libglib-2.0.so', 'libgobject-2.0.so']
Optional-Dependencies	[]
Build-Dependencies	['docbook-xsl', 'gi-docgen', 'git', 'glib2-devel', 'gobject-introspection', 'meson', 'python-docutils']
Provides	['libjson-glib-1.0.so']
Builddate	13-09-2025 20:13:09
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.1-or-later']
Hash	3c2ec1b51d45f7c2d0cee7d28520b0772cc6d01fa09b808536e08dca7dd638eb

# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>

pkgbase=json-glib
pkgname=(
  json-glib
  json-glib-docs
)
pkgver=1.10.8
pkgrel=1
pkgdesc="JSON library built on GLib"
url="https://gnome.pages.gitlab.gnome.org/json-glib/"
arch=(x86_64)
license=(LGPL-2.1-or-later)
depends=(
  glib2
  glibc
)
makedepends=(
  docbook-xsl
  gi-docgen
  git
  glib2-devel
  gobject-introspection
  meson
  python-docutils
)
source=("git+https://gitlab.gnome.org/GNOME/json-glib.git?signed#tag=$pkgver")
b2sums=('fddbe1c61075a56c58d82338423f051653623c124cb0898d50711a13aaae510e5b98874849defe420494e795e453fb9018feec768a2bb928c27caefadcc26739')
validpgpkeys=(
  53EF3DC3B63E2899271BD26322E8091EEA11BBB7 # Emmanuele Bassi <ebassi@gnome.org>
)

prepare() {
  cd json-glib
}

build() {
  local meson_options=(
    -D installed_tests=false
    -D man=true
  )

  arch-meson json-glib build "${meson_options[@]}"
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package_json-glib() {
  depends+=(libg{lib,object,io}-2.0.so)
  provides+=(libjson-glib-1.0.so)

  meson install -C build --destdir "$pkgdir"

  mkdir -p doc/usr/share
  mv {"$pkgdir",doc}/usr/share/doc
}

package_json-glib-docs() {
  pkgdesc+=" (documentation)"
  depends=()

  mv doc/* "$pkgdir"
}

# vim:set sw=2 sts=-1 et: