Name	kbd
Description	Keytable files and keyboard utilities
Version	2.9.0-1
Package Base	kbd
Homepage	http://www.kbd-project.org
Maintainers	['Tobias Powalowski <tpowa@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/kbd
Sources	['fix-euro2.patch', 'git+https://git.kernel.org/pub/scm/linux/kernel/git/legion/kbd.git#tag=v2.9.0?signed', 'vlock.pam']
Dependencies	['glibc', 'gzip', 'pam']
Optional-Dependencies	[]
Build-Dependencies	['check', 'git']
Provides	['vlock']
Builddate	03-10-2025 19:22:16
Architecture	x86_64
Distro-Version
Licenses	['GPL-2.0-or-later']
Hash	87a5d23464db3f62e7de607c0848b51a825657c66d705fd62af208f67d07d131

# Maintainer: Tobias Powalowski <tpowa@archlinux.org>

pkgname=kbd
pkgver=2.9.0
pkgrel=1
pkgdesc="Keytable files and keyboard utilities"
arch=('x86_64')
url="http://www.kbd-project.org"
license=('GPL-2.0-or-later')
depends=(
  glibc
  gzip
  pam
)
makedepends=(
  check
  git
)
source=(
  git+https://git.kernel.org/pub/scm/linux/kernel/git/legion/kbd.git#tag=v$pkgver?signed
  fix-euro2.patch
  vlock.pam
)
backup=('etc/pam.d/vlock')
provides=('vlock')
conflicts=('vlock')
replaces=('vlock')
b2sums=('08c9b775b3e5f0a7918755dfb90610c61b592defd439dd38a48bff579fc8ccac56d9cfa02dbac13141eb7f0f6e91bd78a8ee1c75cd96405719a17f969d1c1963'
        'd122ddb1a86e7a282df8e438903f94d697e3d18a24154d976334e6b54b8f1cf1df432cf8dbcd98daa55014ada462f284d0319fbf015554266e91f4d2a8bf812b'
        '104543e72331a633572a26059e6dce1f25c3c8d6deabb855dd94bfffb72edf8a53a58c6ea7ef6806dd80bcd6ab0aa47cc1a45cc0cd90330be6514ff7591b5140')
validpgpkeys=(
  '7F2A3D07298149A0793C9A4EA45ABA544CFFD434' #Alexey Gladkov 
)

prepare() {
  cd "${pkgname}"
  # rename keymap files with the same names
  # this is needed because when only name of keymap is specified
  # loadkeys loads the first keymap it can find, which is bad (see FS#13837)
  # this should be removed when upstream adopts the change
  mv data/keymaps/i386/qwertz/cz{,-qwertz}.map
  mv data/keymaps/i386/olpc/es{,-olpc}.map
  mv data/keymaps/i386/olpc/pt{,-olpc}.map
  mv data/keymaps/i386/fgGIod/trf{,-fgGIod}.map
  mv data/keymaps/i386/colemak/{en-latin9,colemak}.map
  # fix euro2 #28213
  patch -Np1 -i ../fix-euro2.patch
  autoreconf -if
}

build() {
  cd "${pkgname}"
  ./configure --prefix=/usr \
              --sysconfdir=/etc \
              --datadir=/usr/share/kbd \
              --mandir=/usr/share/man \
              --enable-optional-progs \
              --disable-tests
  make KEYCODES_PROGS=yes RESIZECONS_PROGS=yes
}

package() {
  cd "${pkgname}"
  make KEYCODES_PROGS=yes RESIZECONS_PROGS=yes DESTDIR="${pkgdir}" install
  install -Dm644 ../vlock.pam "${pkgdir}"/etc/pam.d/vlock
}