Name	kde-cli-tools
Description	Tools based on KDE Frameworks to better interact with the system
Version	6.6.0-1
Package Base	kde-cli-tools
Homepage	https://kde.org/plasma-desktop/
Maintainers	['Antonio Rojas <arojas@archlinux.org>', 'Felix Yan <felixonmars@archlinux.org>']
Contributors	['Andrea Scarpino <andrea@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/kde-cli-tools
Sources	['https://download.kde.org/stable/plasma/6.6.1/kde-cli-tools-6.6.1.tar.xz', 'https://download.kde.org/stable/plasma/6.6.1/kde-cli-tools-6.6.1.tar.xz.sig']
Dependencies	['gcc-libs', 'glibc', 'kcmutils', 'kcompletion', 'kconfig', 'kcoreaddons', 'kdesu', 'ki18n', 'kiconthemes', 'kio', 'kparts', 'kservice', 'kwidgetsaddons', 'kwindowsystem', 'qt6-base', 'qt6-svg', 'sh']
Optional-Dependencies	[]
Build-Dependencies	['extra-cmake-modules', 'kdoctools']
Provides	[]
Builddate	17-02-2026 10:19:38
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.0-or-later']
Hash	7900e5bdd6c9bd458e0affb5088640dccbbad11c88e6d4d554abe0f689a5afb8

# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>

pkgname=kde-cli-tools
pkgver=6.6.1
_dirver=$(echo $pkgver | cut -d. -f1-3)
pkgrel=1
pkgdesc='Tools based on KDE Frameworks to better interact with the system'
arch=(x86_64)
url='https://kde.org/plasma-desktop/'
license=(LGPL-2.0-or-later)
depends=(gcc-libs
         glibc
         kcmutils
         kcompletion
         kconfig
         kcoreaddons
         kdesu
         ki18n
         kiconthemes
         kio
         kparts
         kservice
         kwidgetsaddons
         kwindowsystem
         qt6-base
         qt6-svg
         sh)
makedepends=(extra-cmake-modules
             kdoctools)
groups=(plasma)
source=(https://download.kde.org/stable/plasma/$_dirver/$pkgname-$pkgver.tar.xz{,.sig})
sha256sums=('28810d0b4407d0ac752f9420ecd843af2f5568751fc1c70d114620f0596fdeec'
            'SKIP')
validpgpkeys=('E0A3EB202F8E57528E13E72FD7574483BB57B18D'  # Jonathan Esk-Riddell <jr@jriddell.org>
              '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D'  # Bhushan Shah <bshah@kde.org>
              'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson <davidedmundson@kde.org>
              '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart@gmail.com>

build() {
  cmake -B build  -S $pkgname-$pkgver \
    -DCMAKE_INSTALL_LIBEXECDIR=lib \
    -DBUILD_TESTING=OFF
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}