Name	kguiaddons
Description	Addons to QtGui
Version	6.23.0-1
Package Base	kguiaddons
Homepage	https://community.kde.org/Frameworks
Maintainers	['Antonio Rojas <arojas@archlinux.org>', 'Felix Yan <felixonmars@archlinux.org>', 'Tomaz Canabrava <tcanabrava@archlinux.org>']
Contributors	['Andrea Scarpino <andrea@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/kguiaddons
Sources	['https://download.kde.org/stable/frameworks/6.23/kguiaddons-6.23.0.tar.xz', 'https://download.kde.org/stable/frameworks/6.23/kguiaddons-6.23.0.tar.xz.sig']
Dependencies	['gcc-libs', 'glibc', 'libx11', 'qt6-base', 'wayland']
Optional-Dependencies	['pyside6', 'qt6-declarative']
Build-Dependencies	['doxygen', 'extra-cmake-modules', 'plasma-wayland-protocols', 'pyside6', 'python-build', 'python-setuptools', 'qt6-declarative', 'qt6-tools', 'wayland-protocols']
Provides	[]
Builddate	14-02-2026 15:58:08
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.0-only', 'LGPL-3.0-only']
Hash	b76ddc1000ed9ae76bf2b9e457cb0a262c53e5462f01f577ca9b2082ad6b2c9b

# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>

pkgname=kguiaddons
pkgver=6.23.0
pkgrel=2
pkgdesc='Addons to QtGui'
arch=(x86_64)
url='https://community.kde.org/Frameworks'
license=(LGPL-2.0-only LGPL-3.0-only)
depends=(gcc-libs
         glibc
         libx11
         qt6-base
         wayland)
makedepends=(doxygen
             extra-cmake-modules
             plasma-wayland-protocols
             pyside6
             python-build
             python-setuptools
             qt6-declarative
             qt6-tools
             wayland-protocols)
optdepends=('pyside6: Python bindings'
            'qt6-declarative: QML bindings')
groups=(kf6)
source=(https://download.kde.org/stable/frameworks/${pkgver%.*}/$pkgname-$pkgver.tar.xz{,.sig})
sha256sums=('b9c5ad9fd8fd8aeff2ae01b1317a0dad3011e4259e50e4f2e5685fee00047b48'
            'SKIP')
validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB  # David Faure <faure@kde.org>
              E0A3EB202F8E57528E13E72FD7574483BB57B18D  # Jonathan Esk-Riddell <jr@jriddell.org>
              90A968ACA84537CC27B99EAF2C8DF587A6D4AAC1) # Nicolas Fella <nicolas.fella@kde.org>              )

build() {
  cmake -B build -S $pkgname-$pkgver \
    -DBUILD_TESTING=OFF
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}