Name	leancrypto
Description	Lean cryptographic library usable for bare-metal environments
Version	1.6.0-1
Package Base	leancrypto
Homepage	https://leancrypto.org
Maintainers	['Andreas Radke <andyrtr@archlinux.org>', 'Andreas Radke <andyrtr@archlinux.org> ']
Contributors	['Pan Lanlan <abbypan@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/leancrypto
Sources	['leancrypto-1.6.0.tar.gz::https://github.com/smuellerDD/leancrypto/archive/refs/tags/v1.6.0.tar.gz']
Dependencies	['glibc']
Optional-Dependencies	[]
Build-Dependencies	['meson']
Provides	[]
Builddate	26-10-2025 08:39:57
Architecture	x86_64
Distro-Version
Licenses	['GPL-2.0-or-later', 'LicenseRef-BSDvariant', 'LicenseRef-leancrypto']
Hash	2a20a50708410f2c36c7a407e2ab78d05595ff94c85776f8b3b55753c8b0c678

# Maintainer: Andreas Radke <andyrtr@archlinux.org> 
# Contributor: Pan Lanlan <abbypan@gmail.com>

pkgname=leancrypto
pkgver=1.6.0
pkgrel=1
pkgdesc="Lean cryptographic library usable for bare-metal environments"
arch=('x86_64')
license=('GPL-2.0-or-later'
         'LicenseRef-BSDvariant'
         'LicenseRef-leancrypto')
url="https://leancrypto.org"
depends=('glibc')
makedepends=('meson')
source=("$pkgname-$pkgver.tar.gz::https://github.com/smuellerDD/leancrypto/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('b5057cfb990108c4a9f21832f1f35f3d98115012d1628e00650558e6b49e8285')

build() {
  arch-meson $pkgname-$pkgver build

  # Print config
  meson configure build

  meson compile -C build
}

check() {
  # may take pretty long
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"

  install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" $pkgname-$pkgver/LICENSE{,.bsd,.gplv2}
}