Name	libadwaita
Description	Building blocks for modern adaptive GNOME applications
Version	1:1.8.4-1
Package Base	libadwaita
Homepage	https://gnome.pages.gitlab.gnome.org/libadwaita/
Maintainers	['Fabian Bornschein <fabiscafe@archlinux.org>', 'Jan Alexander Steffens (heftig) <heftig@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libadwaita
Sources	['git+https://gitlab.gnome.org/GNOME/libadwaita.git#tag=1.8.4']
Dependencies	['appstream', 'fribidi', 'glib2', 'glibc', 'graphene', 'gtk4', 'libgtk-4.so', 'pango']
Optional-Dependencies	[]
Build-Dependencies	['gi-docgen', 'git', 'glib2-devel', 'gobject-introspection', 'meson', 'sassc', 'vala']
Provides	['libadwaita-1.so']
Builddate	02-02-2026 05:46:29
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.1-or-later']
Hash	e355bdda4e96c44d2012198115e22cde94e00f1c803604343329bff2c9f71ee9

# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Maintainer: Fabian Bornschein <fabiscafe@archlinux.org>

pkgbase=libadwaita
pkgname=(
  libadwaita
  libadwaita-demos
  libadwaita-docs
)
pkgver=1.8.4
pkgrel=1
epoch=1
pkgdesc="Building blocks for modern adaptive GNOME applications"
url="https://gnome.pages.gitlab.gnome.org/libadwaita/"
arch=(x86_64)
license=(LGPL-2.1-or-later)
depends=(
  appstream
  fribidi
  glib2
  glibc
  graphene
  gtk4
  pango
)
makedepends=(
  gi-docgen
  git
  glib2-devel
  gobject-introspection
  meson
  sassc
  vala
)
checkdepends=(weston)
source=(
  "git+https://gitlab.gnome.org/GNOME/libadwaita.git#tag=${pkgver/[a-z]/.&}"
)
b2sums=('307d17c74fe504f4e204d7c495f0261ef797e656fc43b867b2b8013fb1213deda75c8dd860e7bbc08d0810405d4e2e298928c14d9f5312fcd17c21b1bb1071f0')

prepare() {
  cd $pkgname
}

build() {
  local meson_options=(
    -D gtk_doc=true
  )

  arch-meson $pkgname build "${meson_options[@]}"
  meson compile -C build
}

check() (
  export XDG_RUNTIME_DIR="$PWD/runtime-dir"
  mkdir -p -m 700 "$XDG_RUNTIME_DIR"

  export WAYLAND_DISPLAY=wl-$pkgbase-$RANDOM
  weston --backend=headless --socket=$WAYLAND_DISPLAY --idle-time=0 &
  _w=$!

  trap "kill $_w; wait" EXIT

  meson test -C build --print-errorlogs
)

_pick() {
  local p="$1" f d; shift
  for f; do
    d="$srcdir/$p/${f#$pkgdir/}"
    mkdir -p "$(dirname "$d")"
    mv "$f" "$d"
    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  done
}

package_libadwaita() {
  depends+=(libgtk-4.so)
  provides+=(libadwaita-1.so)

  meson install -C build --destdir "$pkgdir"

  cd "$pkgdir"

  _pick demo usr/bin/adwaita-1-demo
  _pick demo usr/share/applications/org.gnome.Adwaita1.Demo.desktop
  _pick demo usr/share/icons/hicolor/*/apps/org.gnome.Adwaita1.Demo[-.]*
  _pick demo usr/share/metainfo/org.gnome.Adwaita1.Demo.metainfo.xml

  _pick docs usr/share/doc
}

package_libadwaita-demos() {
  pkgdesc+=" (demo applications)"
  depends=(
    glib2
    glibc
    gtk4
    hicolor-icon-theme
    libadwaita
  )
  mv demo/* "$pkgdir"
}

package_libadwaita-docs() {
  pkgdesc+=" (documentation)"
  depends=()
  mv docs/* "$pkgdir"
}

# vim:set sw=2 sts=-1 et: