Name	libass
Description	A portable library for SSA/ASS subtitles rendering
Version	0.17.4-1
Package Base	libass
Homepage	https://github.com/libass/libass/
Maintainers	['Maxime Gauduin <alucryd@archlinux.org>', 'T.J. Townsend <blakkheim@archlinux.org>']
Contributors	['G_Syme <demichan@mail.upb.de>', 'Giovanni Scafora <giovanni@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libass
Sources	['git+https://github.com/libass/libass.git?signed#tag=0.17.4']
Dependencies	['fontconfig', 'fribidi', 'glibc', 'harfbuzz', 'libfreetype.so', 'libunibreak']
Optional-Dependencies	[]
Build-Dependencies	['git', 'nasm']
Provides	['libass.so']
Builddate	15-07-2025 00:56:40
Architecture	x86_64
Distro-Version
Licenses	['BSD']
Hash	39d4e21ad360e7cf364e85c792af2181ce60c9aa5c5f052a1e5223f45baa291d

# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: G_Syme <demichan@mail.upb.de>

pkgname=libass
pkgver=0.17.4
pkgrel=1
pkgdesc='A portable library for SSA/ASS subtitles rendering'
arch=(x86_64)
url=https://github.com/libass/libass/
license=(BSD)
depends=(
  fontconfig
  fribidi
  glibc
  harfbuzz
  libfreetype.so
  libunibreak
)
makedepends=(
  git
  nasm
)
provides=(libass.so)
source=(git+https://github.com/libass/libass.git?signed#tag=${pkgver})
validpgpkeys=(
  5458C3100671F252B0F4C7708079D18C21AAAAFF # Oleg Oshmyan (Chortos-2) <chortos@inbox.lv>
  5EE63F2A71BF132CFE3567E1DFFE615F2824C720 # Oneric <oneric@oneric.de>
)
b2sums=('e7790a6318205c8f3383d205acd9befe779014f17ef8d51c37ca19086efba25cf12d22b0af1eeec7e795e9dd824924ebc569ef6c6518276c9dbe10a26337ed27')

prepare() {
  cd libass
  ./autogen.sh
}

build() {
  cd libass
  ./configure \
    --prefix=/usr \
    --enable-fontconfig \
    --enable-libunibreak
  make
}

package() {
  cd libass
  make DESTDIR="${pkgdir}" install
  install -Dm 644 COPYING -t "${pkgdir}"/usr/share/licenses/libass/
}

# vim: ts=2 sw=2 et: