Name	libasyncns
Description	A C library for executing name service queries asynchronously
Version	1:0.8+r3+g68cd5af-3
Package Base	libasyncns
Homepage	https://0pointer.net/lennart/projects/libasyncns/
Maintainers	['Jan Alexander Steffens (heftig) <heftig@archlinux.org>', 'T.J. Townsend <blakkheim@archlinux.org>']
Contributors	['Corrado Primier <bardo@aur.archlinux.org>', 'Daniel J Griffiths <ghost1227@archlinux.us>', 'Eric Belanger <belanger@astro.umontreal.ca>', 'William Rea <sillywilly@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libasyncns
Sources	['git+https://git.0pointer.net/clone/libasyncns.git#commit=68cd5aff1467638c086f1bedcc750e34917168e4']
Dependencies	['glibc']
Optional-Dependencies	[]
Build-Dependencies	['git', 'lynx']
Provides	[]
Builddate	12-07-2024 21:22:47
Architecture	x86_64
Distro-Version
Licenses	['LGPL']
Hash	de65e601391ace5c126e863ad67245b03cfe87f46c12b509668f3da2419bbf15

# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Corrado Primier <bardo@aur.archlinux.org>
# Contributor: Eric Belanger <belanger@astro.umontreal.ca>
# Contributor: William Rea <sillywilly@gmail.com>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>

pkgname=libasyncns
pkgver=0.8+r3+g68cd5af
pkgrel=3
epoch=1
pkgdesc="A C library for executing name service queries asynchronously"
url="https://0pointer.net/lennart/projects/libasyncns/"
arch=(x86_64)
license=(LGPL)
depends=(glibc)
makedepends=(git lynx)
_commit=68cd5aff1467638c086f1bedcc750e34917168e4  # master
source=("git+https://git.0pointer.net/clone/libasyncns.git#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd libasyncns
  git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
}

prepare() {
  cd libasyncns
  NOCONFIGURE=1 ./bootstrap.sh
}

build() {
  cd libasyncns
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
      --disable-static
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd libasyncns
  make DESTDIR="$pkgdir" install
}

# vim:set sw=2 sts=-1 et: