Name	libb2
Description	C library providing BLAKE2b, BLAKE2s, BLAKE2bp, BLAKE2sp hash functions
Version	0.98.1-3
Package Base	libb2
Homepage	https://blake2.net/
Maintainers	['Antonio Rojas <arojas@archlinux.org>']
Contributors	['Jesin <Jesin00@gmail.com>', 'Lex Black <autumn-wind@web.de>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libb2
Sources	['git+https://github.com/BLAKE2/libb2#tag=v0.98.1']
Dependencies	['gcc-libs', 'glibc']
Optional-Dependencies	[]
Build-Dependencies	['git']
Provides	[]
Builddate	03-07-2024 23:48:20
Architecture	x86_64
Distro-Version
Licenses	['CC0-1.0']
Hash	c556a0b37611e9a09f4ff18bb29e8a56f7c4cf59ef70d771d1c031dd2c2fc849

# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Lex Black <autumn-wind@web.de>
# Contributor: Jesin <Jesin00@gmail.com>

pkgname=libb2
pkgver=0.98.1
pkgrel=3
arch=(x86_64)
pkgdesc='C library providing BLAKE2b, BLAKE2s, BLAKE2bp, BLAKE2sp hash functions'
url='https://blake2.net/'
license=(CC0-1.0)
depends=(gcc-libs
         glibc)
makedepends=(git)
source=(git+https://github.com/BLAKE2/libb2#tag=v$pkgver)
sha256sums=('eb6b596bc30918427d1e792914f454c1d3e61fef3d4499f6605ede78f835cc1b')

# libb2's build system discards the $CFLAGS variable.
# We can get around this by putting those flags in $CC.
export CC="${CC-cc} $CFLAGS"

prepare() {
  cd $pkgname
  autoreconf -vi
}

build() {
  cd $pkgname
  ./configure \
    --prefix=/usr \
    --disable-static \
    --enable-shared \
    --disable-native \
    --enable-fat
  make
}

check() {
  cd $pkgname
  make check
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "$pkgdir"/usr/share/licenses/$pkgname
}