Name	libdeflate
Description	Heavily optimized library for DEFLATE/zlib/gzip compression and decompression
Version	1.25-1
Package Base	libdeflate
Homepage	https://github.com/ebiggers/libdeflate
Maintainers	['Maxime Gauduin <alucryd@archlinux.org>']
Contributors	['Chocobo1 <chocobo1@archlinux.net>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libdeflate
Sources	['git+https://github.com/ebiggers/libdeflate.git#tag=c8c56a20f8f621e6a966b716b31f1dedab6a41e3']
Dependencies	['glibc']
Optional-Dependencies	[]
Build-Dependencies	['cmake', 'git', 'ninja']
Provides	['libdeflate.so']
Builddate	05-12-2025 22:47:29
Architecture	x86_64
Distro-Version
Licenses	['MIT']
Hash	4e9b5d01558db0cddfbd2a6a48ed6baf92bbe65af4d0dd1ae390206fe76080ee

# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Chocobo1 <chocobo1@archlinux.net>

pkgname=libdeflate
pkgver=1.25
pkgrel=1
pkgdesc='Heavily optimized library for DEFLATE/zlib/gzip compression and decompression'
arch=(x86_64)
url=https://github.com/ebiggers/libdeflate
license=(MIT)
depends=(glibc)
makedepends=(
  cmake
  git
  ninja
)
provides=(libdeflate.so)
_tag=c8c56a20f8f621e6a966b716b31f1dedab6a41e3
source=(git+https://github.com/ebiggers/libdeflate.git#tag=${_tag})
b2sums=('826b859ef6f99ea71c65e51504b04524b6f7ab636bdbd3bb5aac61d52e30d276060842cafae854f839f32bdf57d975dafd98033dc06a0d47207321eafb821870')

pkgver() {
  cd libdeflate
  git describe --tags | sed 's/^v//'
}

build() {
  cmake -S libdeflate -B build -G Ninja \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLIBDEFLATE_BUILD_STATIC_LIB=OFF \
    -DLIBDEFLATE_BUILD_TESTS=ON
  cmake --build build
}

check() {
  ctest --test-dir build
}

package() {
  DESTDIR="${pkgdir}" cmake --install build
  install -Dm 644 libdeflate/COPYING -t "${pkgdir}"/usr/share/licenses/libdeflate/
}

# vim ts=2 sw=2 et: