Name	libdovi
Description	Library to read and write Dolby Vision metadata
Version	3.3.2-1
Package Base	libdovi
Homepage	https://github.com/quietvoid/dovi_tool/tree/main/dolby_vision
Maintainers	['Maxime Gauduin <alucryd@archlinux.org>', 'Maxime Gauduin <alucryd@archlinux>org>']
Contributors	['quietvoid <tcChlisop0@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libdovi
Sources	['git+https://github.com/quietvoid/dovi_tool.git#tag=4fd2b2235c9f93582dd4a00e65ee34a07800afd7']
Dependencies	['gcc-libs', 'glibc']
Optional-Dependencies	[]
Build-Dependencies	['cargo-c', 'git', 'rust']
Provides	['libdovi.so']
Builddate	26-07-2025 00:07:10
Architecture	x86_64
Distro-Version
Licenses	['MIT']
Hash	9c0c9ee16900e3ec0939e8a4bfb1c4c53104da267ce8cf6861d75694f237dacf

# Maintainer: Maxime Gauduin <alucryd@archlinux>org>
# Contributor: quietvoid <tcChlisop0@gmail.com>

pkgname=libdovi
pkgver=3.3.2
pkgrel=1
pkgdesc='Library to read and write Dolby Vision metadata'
arch=(x86_64)
url=https://github.com/quietvoid/dovi_tool/tree/main/dolby_vision
license=(MIT)
depends=(
  gcc-libs
  glibc
)
makedepends=(
  cargo-c
  git
  rust
)
provides=(libdovi.so)
_tag=4fd2b2235c9f93582dd4a00e65ee34a07800afd7
source=(git+https://github.com/quietvoid/dovi_tool.git#tag=${_tag})
b2sums=('40aefc4476b3fb674d2f2fe241de1e8e8b91658c8d5c9d7c729d371bbbb5b70955210d23b3cd088ae2001963f9aa15c29ceb4fa3abf15762f66d44efd6c3ae0e')

prepare() {
  cargo fetch \
    --manifest-path dovi_tool/dolby_vision/Cargo.toml
}

#pkgver() {
#  cd dovi_tool
#  git describe --tags | sed 's/^libdovi-//'
#}

build() {
  cargo cbuild \
    --release \
    --frozen \
    --prefix=/usr \
    --manifest-path dovi_tool/dolby_vision/Cargo.toml
}

check() {
  cargo test \
    --release \
    --frozen \
    --all-features \
    --manifest-path dovi_tool/dolby_vision/Cargo.toml
}

package() {
  cd dovi_tool/dolby_vision
  cargo cinstall \
    --release \
    --frozen \
    --prefix /usr \
    --destdir "${pkgdir}"
  install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/libdovi/
}

# vim: ts=2 sw=2 et: