Name	libffi
Description	Portable foreign function interface library
Version	3.5.2-1
Package Base	libffi
Homepage	https://sourceware.org/libffi/
Maintainers	['David Runge <dvzrv@archlinux.org>', 'Levente Polyak <anthraxx[at]archlinux[dot]org>']
Contributors	['Bartłomiej Piotrowski <bpiotrowski@archlinux.org>', 'Jan de Groot <jgc@archlinux.org>', 'Stéphane Gaudreault <stephane@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libffi
Sources	['libffi-3.5.2.tar.gz::https://github.com/libffi/libffi/archive/refs/tags/v3.5.2.tar.gz']
Dependencies	['glibc']
Optional-Dependencies	[]
Build-Dependencies	[]
Provides	['libffi.so']
Builddate	02-08-2025 22:41:02
Architecture	x86_64
Distro-Version
Licenses	['MIT']
Hash	6855aa68ae506c124f9e62c6be3dd40dd750a050d7126d5265118128638da5c3

# Maintainer: David Runge <dvzrv@archlinux.org>
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>

pkgname=libffi
pkgver=3.5.2
pkgrel=1
pkgdesc='Portable foreign function interface library'
arch=(x86_64)
url='https://sourceware.org/libffi/'
_url="https://github.com/libffi/libffi"
license=(MIT)
depends=(glibc)
checkdepends=(dejagnu)
provides=(libffi.so)
source=($pkgname-$pkgver.tar.gz::$_url/archive/refs/tags/v$pkgver.tar.gz)
sha256sums=('dd19253d3007f366319a51d248a40c9e5fcace4498cbea990b566291844e4e30')
b2sums=('4aa7ecdbb7abc862f876cc0b0484f944fe6c49633071d36a964ad94f06d02ee08c76dceed5d6897da02c357515033f084a9a4da3a22bdd559316a5dca736332d')

prepare() {
  cd $pkgname-$pkgver
  autoreconf -fiv
}

build() {
  local configure_options=(
    # remove --disable-exec-static-tramp once ghc and gobject-introspection
    # work fine with it enabled (https://github.com/libffi/libffi/pull/647)
    --disable-exec-static-tramp
    --disable-multi-os-directory
    --disable-static
    --enable-pax_emutramp
    --prefix=/usr
  )

  cd $pkgname-$pkgver
  ./configure "${configure_options[@]}"
  make
}

check() {
  make -C $pkgname-$pkgver check
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm 644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
  install -Dm 644 README.md -t "$pkgdir"/usr/share/doc/$pkgname
}

# vim:set ts=2 sw=2 et: