Name	libfido2
Description	Library functionality for FIDO 2.0, including communication with a device over USB
Version	1.16.0-2
Package Base	libfido2
Homepage	https://developers.yubico.com/libfido2/
Maintainers	['Antonio Rojas <arojas@archlinux.org>', 'Levente Polyak <anthraxx[at]archlinux[dot]org>']
Contributors	['Karol Babioch <karol@babioch.de>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libfido2
Sources	['https://developers.yubico.com/libfido2/Releases/libfido2-1.16.0.tar.gz', 'https://developers.yubico.com/libfido2/Releases/libfido2-1.16.0.tar.gz.sig']
Dependencies	['glibc', 'hidapi', 'libcbor', 'libcbor.so', 'libudev.so', 'openssl', 'systemd-libs', 'zlib']
Optional-Dependencies	[]
Build-Dependencies	['cmake', 'systemd']
Provides	['libfido2.so']
Builddate	15-06-2025 14:38:31
Architecture	x86_64
Distro-Version
Licenses	['BSD-2-Clause']
Hash	2a516c4d438f7a970d23868f2496a11d08bd6b98c13e6f1ef6d03540e2944265

# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Karol Babioch <karol@babioch.de>

pkgname=libfido2
pkgver=1.16.0
pkgrel=2
pkgdesc='Library functionality for FIDO 2.0, including communication with a device over USB'
url='https://developers.yubico.com/libfido2/'
arch=('x86_64')
license=('BSD-2-Clause')
depends=('glibc' 'openssl' 'libcbor' 'libcbor.so' 'hidapi' 'systemd-libs'  'libudev.so' 'zlib')
makedepends=('cmake' 'systemd')
provides=('libfido2.so')
source=("https://developers.yubico.com/libfido2/Releases/libfido2-${pkgver}.tar.gz"{,.sig})
sha512sums=('487424a993ff3c9cb48f96a8e15bdd1b0105b7ad840c6d44cdd683a53bc4fe500a42f51d1d0ab75f8e000c081af57ba95cb4c04c641ea4322c23a407d291f470'
            'SKIP')
b2sums=('857b24c5cf38db9620fc567f42b7af2a7fd4ca24433af1113ca41a040c2f8242abaa99fe2a3826640d42348221895b88064d447a4b064de6e04ae48add42de34'
        'SKIP')
validpgpkeys=(
  'EE90AE0D19774C8386628FAAB428949EF7914718' # pedro martelletto <pedro@yubico.com>
  '1D7308B0055F5AEF36944A8F27A9C24D9588EA0F' # Aveen Ismail <aveen.ismail@yubico.com>
  '7FBB6186957496D58C751AC20E777DD85755AA4A' # Konstantinos Georgantas <kostas@yubico.com>
  '78D997D53E9C0A2A205392ED14A19784723C9988' # Ludvig Michaelsson <ludvig.michaelsson@yubico.com>
)

build() {
  cd ${pkgname}-${pkgver}
  # do not use bundled udev rules superseded by systemd
  cmake -B build \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DCMAKE_BUILD_TYPE=None \
    -Wno-dev \
    -S .
  make -C build VERBOSE=1
}

package() {
  cd ${pkgname}-${pkgver}
  make -C build DESTDIR="${pkgdir}" install
  install -Dm 644 NEWS README.adoc -t "${pkgdir}/usr/share/doc/${pkgname}"
  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

# vim: ts=2 sw=2 et: