Name	libgoa
Description	Single sign-on framework for GNOME - client library
Version	3.56.4-1
Package Base	gnome-online-accounts
Homepage	https://wiki.gnome.org/Projects/GnomeOnlineAccounts
Maintainers	['Fabian Bornschein <fabiscafe@archlinux.org>', 'Jan Alexander Steffens (heftig) <heftig@archlinux.org>']
Contributors	['Ionut Biru <ibiru@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/gnome-online-accounts
Sources	['git+https://gitlab.gnome.org/GNOME/gnome-online-accounts.git#tag=3.56.4']
Dependencies	['glib2', 'glibc', 'libgio-2.0.so', 'libglib-2.0.so', 'libgobject-2.0.so']
Optional-Dependencies	[]
Build-Dependencies	['git', 'gi-docgen', 'glib2-devel', 'gobject-introspection', 'meson', 'vala']
Provides	['libgoa-1.0.so']
Builddate	06-02-2026 03:33:27
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.0-or-later']
Hash	a35284be276c1a8c25becf28d5a84c8360db697820198da2af85ff8860ecc2dd

# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Maintainer: Fabian Bornschein <fabiscafe@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>

pkgbase=gnome-online-accounts
pkgname=(
  gnome-online-accounts
  libgoa
)
pkgver=3.56.4
pkgrel=1
pkgdesc="Single sign-on framework for GNOME"
url="https://wiki.gnome.org/Projects/GnomeOnlineAccounts"
arch=(x86_64)
license=(LGPL-2.0-or-later)
depends=(
  dbus
  dconf
  gcc-libs
  gcr-4
  glib2
  glibc
  gtk4
  hicolor-icon-theme
  json-glib
  keyutils
  krb5
  libadwaita
  librest
  libsecret
  libsoup3
  libxml2
)
makedepends=(
  git
  gi-docgen
  glib2-devel
  gobject-introspection
  meson
  vala
)
source=(
  # GOA tags use SSH signatures which makepkg doesn't understand
  "git+https://gitlab.gnome.org/GNOME/gnome-online-accounts.git#tag=$pkgver"
)
b2sums=('247ce511348191a40db547d5ded45f321df0dd768368651eb92ff30e8ed9481c1952dcf492cf139fd71edaf9717ba5bf39012936420ee3cb531434c8f5a3e647')

prepare() {
  cd $pkgname
}

build() {
  local meson_options=(
    -D documentation=true
    -D man=true
  )

  arch-meson $pkgname build "${meson_options[@]}"
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

_pick() {
  local p="$1" f d; shift
  for f; do
    d="$srcdir/$p/${f#$pkgdir/}"
    mkdir -p "$(dirname "$d")"
    mv "$f" "$d"
    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  done
}

package_gnome-online-accounts() {
  depends+=("libgoa=$pkgver-$pkgrel")
  optdepends=(
    'epiphany: (or another modern browser): OAuth authentication'
    'gvfs-goa: Virtual file systems, e.g. OwnCloud'
    'gvfs-google: Google Drive'
    'gvfs-onedrive: Microsoft OneDrive'
  )
  provides=(libgoa-backend-1.0.so)

  meson install -C build --destdir "$pkgdir"

  cd "$pkgdir"

  _pick goa usr/include/goa-1.0/goa
  _pick goa usr/lib/libgoa-1.0.so*
  _pick goa usr/lib/girepository-1.0/Goa-1.0.typelib
  _pick goa usr/lib/goa-1.0/include
  _pick goa usr/lib/pkgconfig/goa-1.0.pc
  _pick goa usr/share/gir-1.0/Goa-1.0.gir
  _pick goa usr/share/vala/vapi/goa-1.0.*
  _pick goa usr/share/doc
}

package_libgoa() {
  pkgdesc+=" - client library"
  depends=(
    glib2 libg{lib,object,io}-2.0.so
    glibc
  )
  provides=(libgoa-1.0.so)

  mv goa/* "$pkgdir"
}

# vim:set sw=2 sts=-1 et: