Name	libgpg-error
Description	Support library for libgcrypt
Version	1.59-1
Package Base	libgpg-error
Homepage	https://www.gnupg.org
Maintainers	['Andreas Radke <andyrtr@archlinux.org>']
Contributors	['judd <jvinet@zeroflux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libgpg-error
Sources	['https://www.gnupg.org/ftp/gcrypt/libgpg-error/libgpg-error-1.59.tar.bz2', 'https://www.gnupg.org/ftp/gcrypt/libgpg-error/libgpg-error-1.59.tar.bz2.sig']
Dependencies	['glibc', 'sh']
Optional-Dependencies	[]
Build-Dependencies	[]
Provides	[]
Builddate	18-02-2026 12:38:28
Architecture	x86_64
Distro-Version
Licenses	['BSD-3-Clause OR LGPL-2.1-or-later', 'FSFULLR', 'GPL-2.0-or-later', 'LGPL-2.1-or-later']
Hash	182b6b3c28b0607880d05c37d90c56df1cfaa125434e54cfe29c42476dcb72c5

# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: judd <jvinet@zeroflux.org>

pkgname=libgpg-error
pkgver=1.59
pkgrel=1
pkgdesc="Support library for libgcrypt"
arch=(x86_64)
url="https://www.gnupg.org"
license=(LGPL-2.1-or-later
         'BSD-3-Clause OR LGPL-2.1-or-later'
         FSFULLR
         GPL-2.0-or-later)
depends=('glibc' 'sh')
# https://git.gnupg.org/cgi-bin/gitweb.cgi?p=libgpg-error.git;a=summary
source=(https://www.gnupg.org/ftp/gcrypt/libgpg-error/${pkgname}-${pkgver}.tar.bz2{,.sig})
# https://www.gnupg.org/download/integrity_check.html
sha256sums=('a19bc5087fd97026d93cb4b45d51638d1a25202a5e1fbc3905799f424cfa6134'
            'SKIP')
validpgpkeys=('6DAA6E64A76D2840571B4902528897B826403ADA') # Werner Koch (dist signing 2020)
validpgpkeys+=('AC8E115BF73E2D8D47FA9908E98E9B2D19C6C8BD') # Niibe Yutaka (GnuPG Release Key)

prepare() {
  cd ${pkgname}-${pkgver}
  autoreconf -vfi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr
  make
}

check() {
  cd ${pkgname}-${pkgver}
  make check
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}/" install
  install -vDm 644 COPYING{,.LIB} -t "${pkgdir}"/usr/share/licenses/${pkgname}/
}