Name	libgudev
Description	GObject bindings for libudev
Version	238-3
Package Base	libgudev
Homepage	https://gitlab.gnome.org/GNOME/libgudev
Maintainers	['Jan Alexander Steffens (heftig) <heftig@archlinux.org>']
Contributors	['Evangelos Foutras <foutrelis@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libgudev
Sources	['git+https://gitlab.gnome.org/GNOME/libgudev.git#tag=238']
Dependencies	['gcc-libs', 'glib2', 'glibc', 'libglib-2.0.so', 'libgobject-2.0.so', 'libsystemd', 'libudev.so']
Optional-Dependencies	[]
Build-Dependencies	['git', 'glib2-devel', 'glibc-locales', 'gobject-introspection', 'gtk-doc', 'meson', 'systemd', 'umockdev', 'vala']
Provides	['libgudev-1.0.so']
Builddate	14-05-2025 15:17:26
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.1-or-later']
Hash	2eb60ecec6a7c1c2b18ae9c259afeb45ad18abb4cdfa486ff38f333557ed520f

# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Evangelos Foutras <foutrelis@archlinux.org>

pkgname=libgudev
pkgver=238
pkgrel=3
pkgdesc="GObject bindings for libudev"
url="https://gitlab.gnome.org/GNOME/libgudev"
arch=(x86_64)
license=(LGPL-2.1-or-later)
depends=(
  gcc-libs
  glib2
  glibc
  libsystemd
)
makedepends=(
  git
  glib2-devel
  glibc-locales
  gobject-introspection
  gtk-doc
  meson
  systemd
  umockdev
  vala
)
source=("git+$url.git#tag=$pkgver")
b2sums=('6da9512d87154fbd62aae044a39abd84bee451f5a21203180062c369ebedf2ee1bc7672408cf806918111397bc74be58314e6c3155e638137603d11012a4355f')

prepare() {
  cd libgudev
}

build() {
  local meson_options=(
    -D gtk_doc=true
  )

  arch-meson libgudev build "${meson_options[@]}"
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  depends+=(
    libg{lib,object}-2.0.so
    libudev.so
  )
  provides+=(libgudev-1.0.so)

  meson install -C build --destdir "$pkgdir"
}

# vim:set sw=2 sts=-1 et: