Name	libical
Description	An open source reference implementation of the icalendar data type and serialization format
Version	3.0.20-3
Package Base	libical
Homepage	https://github.com/libical/libical
Maintainers	['Andreas Radke <andyrtr@archlinux.org>', 'Lukas Fleischer <lfleischer@archlinux.org>']
Contributors	['Andrea Scarpino <andrea@archlinux.org>', 'Pierre Schmitz <pierre@archlinux.de>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libical
Sources	['libical-3.0.20.tar.gz::https://github.com/libical/libical/archive/v3.0.20.tar.gz']
Dependencies	['gcc-libs', 'glib2', 'glibc', 'icu', 'libxml2']
Optional-Dependencies	[]
Build-Dependencies	['cmake', 'ninja', 'gtk-doc', 'doxygen', 'vala', 'gobject-introspection']
Provides	[]
Builddate	04-11-2025 18:08:15
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.1-only', 'MPL-2.0']
Hash	628f9626b96c8ada7a31149ffd7213b3ff18ed5ee5f078b751be34fd24aaf9af

# Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>

pkgname=libical
pkgver=3.0.20
pkgrel=3
pkgdesc="An open source reference implementation of the icalendar data type and serialization format"
arch=('x86_64')
url='https://github.com/libical/libical'
license=('LGPL-2.1-only' 'MPL-2.0')
depends=('glibc' 'gcc-libs' 'glib2' 'icu' 'libxml2')
makedepends=('cmake' 'ninja' 'gtk-doc' 'doxygen' 'vala' 'gobject-introspection')
checkdepends=('python-gobject')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/v${pkgver}.tar.gz")
sha512sums=('2506320240ba0e4287b6ef1b90b653eacd51105d392b91f8c772f3b0745fecbf55eecfe81f89413cc56106b71ccca780754df31f5190ffce6c372126e27bf1da')

build() {
  cmake -S "${pkgname}-${pkgver}" -B build -G Ninja \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBEXECDIR=lib \
    -DGOBJECT_INTROSPECTION=true \
    -DICAL_GLIB_VAPI=true \
    -DSHARED_ONLY=true \
    -DCMAKE_DISABLE_FIND_PACKAGE_BerkeleyDB=true
  cmake --build build
}

check() {
  cmake --build build --target test
}

package() {
  DESTDIR="${pkgdir}" cmake --install build
}