Name	libidn2
Description	Free software implementation of IDNA2008, Punycode and TR46
Version	2.3.8-1
Package Base	libidn2
Homepage	https://www.gnu.org/software/libidn/#libidn2
Maintainers	['Christian Hesse <eworm@archlinux.org>', 'Evangelos Foutras <foutrelis@archlinux.org>']
Contributors	['Daurnimator <quae@daurnimator.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libidn2
Sources	['https://ftp.gnu.org/gnu/libidn/libidn2-2.3.8.tar.gz', 'https://ftp.gnu.org/gnu/libidn/libidn2-2.3.8.tar.gz.sig']
Dependencies	['libunistring', 'libunistring.so']
Optional-Dependencies	[]
Build-Dependencies	['ruby-ronn-ng']
Provides	['libidn2.so']
Builddate	08-12-2025 11:36:04
Architecture	x86_64
Distro-Version
Licenses	['GPL2', 'LGPL3']
Hash	1749bdd4c395913df18c57fdd42820d3de88738b7163b7aa254d13e3da7b1d9d

# Maintainer: Evangelos Foutras <foutrelis@archlinux.org>
# Contributor: Daurnimator <quae@daurnimator.com>

pkgname=libidn2
pkgver=2.3.8
pkgrel=1
pkgdesc="Free software implementation of IDNA2008, Punycode and TR46"
arch=('x86_64')
url="https://www.gnu.org/software/libidn/#libidn2"
license=('GPL2' 'LGPL3')
depends=('libunistring')
makedepends=('ruby-ronn-ng')
provides=('libidn2.so')
source=(https://ftp.gnu.org/gnu/libidn/$pkgname-$pkgver.tar.gz{,.sig})
sha256sums=('f557911bf6171621e1f72ff35f5b1825bb35b52ed45325dcdee931e5d3c0787a'
            'SKIP')
validpgpkeys=('B1D2BD1375BECB784CF4F8C4D73CF638C53C06BE') # Simon Josefsson <simon@josefsson.org>

prepare() {
  cd $pkgname-$pkgver
}

build() {
  cd $pkgname-$pkgver

  ./configure \
    --prefix=/usr \
    --disable-static
  make
}

check() {
  cd $pkgname-$pkgver
  make check
}
package() {
  depends+=('libunistring.so')

  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: