Name	libinput-tools
Description	Input device management and event handling library (debug utilities)
Version	1.30.1-1
Package Base	libinput
Homepage	https://wayland.freedesktop.org/libinput/doc/latest/
Maintainers	['Jan Alexander Steffens (heftig) <heftig@archlinux.org>']
Contributors	['Andreas Radke <andyrtr@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libinput
Sources	['git+https://gitlab.freedesktop.org/libinput/libinput.git?signed#tag=1.31.0']
Dependencies	['cairo', 'gcc-libs', 'glib2', 'glibc', 'gtk4', 'libevdev', 'libinput', 'libx11', 'python', 'python-libevdev', 'python-pyudev', 'python-yaml', 'systemd-libs', 'wayland']
Optional-Dependencies	[]
Build-Dependencies	['cairo', 'check', 'git', 'glib2', 'gtk4', 'libx11', 'meson', 'python', 'python-libevdev', 'python-pyudev', 'python-yaml', 'wayland', 'wayland-protocols']
Provides	[]
Builddate	08-12-2025 06:45:45
Architecture	x86_64
Distro-Version
Licenses	['MIT']
Hash	96c4dd66d84fb0b75637daf9c6566b4d51a61c1852af918ba2f473fd2a7c6cb7

# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Andreas Radke <andyrtr@archlinux.org>

pkgbase=libinput
pkgname=(
  libinput
  libinput-tools
)
pkgver=1.31.0
pkgrel=1
pkgdesc="Input device management and event handling library"
url="https://wayland.freedesktop.org/libinput/doc/latest/"
arch=(x86_64)
license=(MIT)
depends=(
  glibc
  libevdev
  libgcc
  libwacom
  lua54
  mtdev
  systemd-libs
)
makedepends=(
  cairo
  check
  git
  glib2
  gtk4
  libx11
  meson
  python
  python-libevdev
  python-pyudev
  python-yaml
  wayland
  wayland-protocols
)
checkdepends=(python-pytest)
source=(
  "git+https://gitlab.freedesktop.org/libinput/libinput.git?signed#tag=$pkgver"
)
b2sums=('a84d2dbc73e33f1ed21b28d525b0e11fc361094f9e584b7ab80a73308a09ff737445c25eaf2b324147ef723d9db82489c407d34cfb262c31edb27f8c2138d268')
validpgpkeys=(
  3C2C43D9447D5938EF4551EBE23B7E70B467F0BF # Peter Hutterer (Who-T) <office@who-t.net>
)

build() {
  local meson_options=(
    # upstream recommends not building docs
    -D documentation=false
  )

  arch-meson libinput build "${meson_options[@]}"
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

_pick() {
  local p="$1" f d; shift
  for f; do
    d="$srcdir/$p/${f#$pkgdir/}"
    mkdir -p "$(dirname "$d")"
    mv "$f" "$d"
    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  done
}

package_libinput() {
  optdepends=('libinput-tools: debug utilities')
  provides=(libinput.so)

  meson install -C build --destdir "$pkgdir"

  (
    cd "$pkgdir"

    _pick tools usr/bin
    _pick tools usr/lib/libinput
    _pick tools usr/share/man
    _pick tools usr/share/zsh
  )

  install -Dm644 libinput/COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}

package_libinput-tools() {
  pkgdesc+=" (debug utilities)"
  depends=(
    cairo
    glib2
    glibc
    gtk4
    libevdev
    libgcc
    libinput
    libx11
    python
    python-libevdev
    python-pyudev
    python-yaml
    systemd-libs
    wayland
  )

  mv tools/* "$pkgdir"

  install -Dm644 libinput/COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}

# vim:set sw=2 sts=-1 et: