Name	libisl
Description	Library for manipulating sets and relations of integer points bounded by linear constraints
Version	0.27-1
Package Base	libisl
Homepage	https://libisl.sourceforge.io
Maintainers	['Frederik Schwan <freswa@archlinux.org>']
Contributors	['Allan McRae <allan@archlinux.org>', 'Andrew Sun <adsun701@gmail.com>', 'Kritias <theodoridisgr@gmail.com>', 'sudokode <sudokode@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libisl
Sources	['https://libisl.sourceforge.io/isl-0.27.tar.xz']
Dependencies	['gmp']
Optional-Dependencies	[]
Build-Dependencies	[]
Provides	['isl', 'libisl.so']
Builddate	02-09-2024 11:45:50
Architecture	x86_64
Distro-Version
Licenses	['MIT']
Hash	55a36e8195e6d9ce2efeb4276c60df6b6e7d94812fa36f8423d5ce664a5d34df

# Maintainer: Frederik Schwan <freswa at archlinux dot org>
# Contributor: Andrew Sun  <adsun701 at gmail dot com>
# Contributor: Kritias     <theodoridisgr at gmail dot com>
# Contributor: sudokode    <sudokode at gmail dot com>
# Contributor: Allan McRae <allan at archlinux dot org>

pkgname=libisl
pkgver=0.27
pkgrel=1
pkgdesc='Library for manipulating sets and relations of integer points bounded by linear constraints'
arch=('x86_64')
url='https://libisl.sourceforge.io'
license=('MIT')
depends=('gmp')
provides=('isl' 'libisl.so')
replaces=('isl')
options=(staticlibs)
source=("https://libisl.sourceforge.io/isl-${pkgver}.tar.xz")
b2sums=('88a68de0b7952eb0038d10aa450b0ab25da4f4aa49fcdf70700ec4131d2686a2a2e9a64e5cb8ac0a53ef5d7cff034e60c449b201ba88a24001ad33f0dd17c732')

build() {
  cd "${srcdir}"/${pkgname#lib}-${pkgver}
  ./configure --prefix=/usr
  make
}

check() {
  cd "${srcdir}"/${pkgname#lib}-${pkgver}
  make check || true
}

package() {
  cd "${srcdir}"/${pkgname#lib}-${pkgver}

  make DESTDIR="${pkgdir}" install

  install -dm755 "${pkgdir}"/usr/share/gdb/auto-load/usr/lib/
  mv "${pkgdir}"/usr/lib/libisl.so.*-gdb.py "${pkgdir}"/usr/share/gdb/auto-load/usr/lib/

  install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}