Name	libjpeg-turbo
Description	JPEG image codec with accelerated baseline compression and decompression
Version	3.1.3-1
Package Base	libjpeg-turbo
Homepage	https://libjpeg-turbo.org/
Maintainers	['David Runge <dvzrv@archlinux.org>']
Contributors	['Allan McRae <allan@archlinux.org>', 'Gaetan Bisson <bisson@archlinux.org>', "Simone Sclavi 'Ito' <darkhado@gmail.com>"]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libjpeg-turbo
Sources	['https://github.com/libjpeg-turbo/libjpeg-turbo//releases/download/3.1.3/libjpeg-turbo-3.1.3.tar.gz', 'https://github.com/libjpeg-turbo/libjpeg-turbo//releases/download/3.1.3/libjpeg-turbo-3.1.3.tar.gz.sig']
Dependencies	['glibc']
Optional-Dependencies	['java-runtime']
Build-Dependencies	['cmake', 'ninja', 'nasm', 'java-environment', 'strip-nondeterminism']
Provides	['libjpeg', 'libjpeg.so', 'libturbojpeg.so']
Builddate	11-12-2025 11:25:34
Architecture	x86_64
Distro-Version
Licenses	['BSD-3-Clause', 'IJG']
Hash	d670ec7aa8bd91099064449b7a6507f5ff805150e1310cfce415318e418933f1

# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: Simone Sclavi 'Ito' <darkhado@gmail.com>

pkgname=libjpeg-turbo
pkgver=3.1.3
pkgrel=1
pkgdesc="JPEG image codec with accelerated baseline compression and decompression"
url="https://libjpeg-turbo.org/"
_url="https://github.com/libjpeg-turbo/libjpeg-turbo/"
arch=(x86_64)
license=(
  BSD-3-Clause
  IJG
)
depends=(glibc)
makedepends=(
  cmake
  ninja
  nasm
  'java-environment>11'
  strip-nondeterminism
)
optdepends=('java-runtime>11: for TurboJPEG Java wrapper')
provides=(
  libjpeg
  libjpeg.so
  libturbojpeg.so
)
source=(
  $_url/releases/download/$pkgver/$pkgname-$pkgver.tar.gz{,.sig}
)
sha512sums=('d3410a072044b4962c1aa08eb144b4e4b959f4f65203dfac4013b14e2fd987b9a6ee9b59f5570980fa691ddf5e9f9d3aa328a63afb487a46c2e76de722f3d693'
            'SKIP')
b2sums=('3c675aa56b3474ca8a27f355d14dd7411d90471564c5916884e87818b7165e73a6c6b416dc2800e31c10dd1390ae88353e81d80eceb2e22c00b6a81ac5cf3d65'
        'SKIP')
validpgpkeys=('0338C8D8D9FDA62CF9C421BD7EC2DBB6F4DBF434') # The libjpeg-turbo Project (Signing key for official binaries) <information@libjpeg-turbo.org>

build() {
  local cmake_options=(
    -B build
    -D CMAKE_INSTALL_PREFIX=/usr
    -D CMAKE_INSTALL_LIBDIR=/usr/lib
    -D CMAKE_BUILD_TYPE=None
    -D ENABLE_STATIC=OFF
    -D WITH_JAVA=ON
    -D WITH_JPEG8=ON
    -G Ninja
    -S $pkgname-$pkgver
    -W no-dev
  )

  cmake "${cmake_options[@]}"
  cmake --build build -v

  # cmake creates non-reproducible jars: https://github.com/libjpeg-turbo/libjpeg-turbo/issues/745
  strip-nondeterminism --timestamp "$SOURCE_DATE_EPOCH" build/java/turbojpeg.jar
}

check() {
  ctest --test-dir build --output-on-failure --stop-on-failure -j$(nproc)
}

package() {
  DESTDIR="$pkgdir" cmake --install build -v

  # header required by some dependents
  # https://bugs.archlinux.org/task/24787
  install -vDm 644 $pkgname-$pkgver/src/jpegint.h "$pkgdir/usr/include"

  install -vDm 644 $pkgname-$pkgver/LICENSE.md -t "$pkgdir/usr/share/licenses/$pkgname/"
  install -vDm 644 $pkgname-$pkgver/README.ijg -t "$pkgdir/usr/share/licenses/$pkgname/"
}