Name	libmicrohttpd
Description	a small C library that is supposed to make it easy to run an HTTP server as part of another application.
Version	1.0.2-1
Package Base	libmicrohttpd
Homepage	https://www.gnu.org/software/libmicrohttpd/
Maintainers	['Christian Hesse <eworm@archlinux.org>', 'Norberto Lopes <shelika@mail.telepac.pt>', 'Sergej Pupykin <pupykin.s+arch@gmail.com>']
Contributors	['Dmitrij D. Czarkoff <czarkoff@gmail.com>', 'Kao Dome <kaodome@gmail.com>', 'Mathias Rohnstock <linksoft@gmx.de>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libmicrohttpd
Sources	['https://ftp.gnu.org/gnu/libmicrohttpd/libmicrohttpd-1.0.2.tar.gz', 'https://ftp.gnu.org/gnu/libmicrohttpd/libmicrohttpd-1.0.2.tar.gz.sig']
Dependencies	['gnutls']
Optional-Dependencies	[]
Build-Dependencies	[]
Provides	['libmicrohttpd.so']
Builddate	14-07-2025 18:14:26
Architecture	x86_64
Distro-Version
Licenses	['LGPL']
Hash	69332849e502b48d63f1eea9d8a6596c52e5399932ea4e93e2702d68284ae5da

# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Norberto Lopes <shelika@mail.telepac.pt>
# Contributor: Kao Dome <kaodome@gmail.com>
# Contributor: Dmitrij D. Czarkoff <czarkoff@gmail.com>
# Contributor: Mathias Rohnstock <linksoft@gmx.de>

pkgname=libmicrohttpd
pkgver=1.0.2
pkgrel=1
pkgdesc='a small C library that is supposed to make it easy to run an HTTP server as part of another application.'
arch=('x86_64')
url='https://www.gnu.org/software/libmicrohttpd/'
license=('LGPL')
depends=('gnutls')
checkdepends=('curl')
provides=('libmicrohttpd.so')
validpgpkeys=('EA812DBEFA5A7EF17DA8F2C1460A317C3326D2AE'  # Evgeny Grin (Karlson2k) <k2k@yandex.ru>
              'D8423BCB326C7907033929C7939E6BE1E29FC3CC') # Christian Grothoff <christian.grothoff@bfh.ch>
source=("https://ftp.gnu.org/gnu/libmicrohttpd/$pkgname-$pkgver.tar.gz"{,.sig})
sha256sums=('df324fcd0834175dab07483133902d9774a605bfa298025f69883288fd20a8c7'
            'SKIP')

build() {
  cd ${pkgname}-${pkgver}

  ./configure \
    --prefix=/usr \
    --disable-dependency-tracking \
    --disable-examples \
    --enable-curl \
    --enable-https \
    --enable-largefile \
    --enable-messages \
    --with-pic
  make
}

check() {
  cd ${pkgname}-${pkgver}

  make check
}

package() {
  cd ${pkgname}-${pkgver}

  make DESTDIR="$pkgdir" install
}