Name	libmodplug
Description	A MOD playing library
Version	0.8.9.0-6
Package Base	libmodplug
Homepage	http://modplug-xmms.sourceforge.net/
Maintainers	['Eric Bélanger <eric@archlinux.org>', 'T.J. Townsend <blakkheim@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libmodplug
Sources	['https://downloads.sourceforge.net/modplug-xmms/libmodplug-0.8.9.0.tar.gz', 'libmodplug-0.8.9.0-no-fast-math.patch']
Dependencies	['gcc-libs']
Optional-Dependencies	[]
Build-Dependencies	[]
Provides	[]
Builddate	12-07-2024 22:40:51
Architecture	x86_64
Distro-Version
Licenses	['custom']
Hash	9b4bccb70ef40e514145fb3f06cf8cb77ca04b639f9e02c8e19139e7736d841d

# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=libmodplug
pkgver=0.8.9.0
pkgrel=6
pkgdesc="A MOD playing library"
arch=('x86_64')
url="http://modplug-xmms.sourceforge.net/"
license=('custom')
depends=('gcc-libs')
source=(https://downloads.sourceforge.net/modplug-xmms/${pkgname}-${pkgver}.tar.gz
        libmodplug-0.8.9.0-no-fast-math.patch)
sha256sums=('457ca5a6c179656d66c01505c0d95fafaead4329b9dbaa0f997d00a3508ad9de'
            '24b97252803b39546199715158ab1d61616755c6c9756f8b2b9b1948477ce4ed')

prepare() {
  cd ${pkgname}-${pkgver}
  # FS#76950 (Gentoo)
  patch -Np1 -i ../libmodplug-0.8.9.0-no-fast-math.patch
  autoreconf -vfi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}