Name	libmpc
Description	Library for the arithmetic of complex numbers with arbitrarily high precision
Version	1.3.1-2
Package Base	libmpc
Homepage	http://www.multiprecision.org/
Maintainers	['Antonio Rojas <arojas@archlinux.org>']
Contributors	['Allan McRae <allan@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libmpc
Sources	['https://ftp.gnu.org/gnu/mpc/mpc-1.3.1.tar.gz', 'https://ftp.gnu.org/gnu/mpc/mpc-1.3.1.tar.gz.sig']
Dependencies	['glibc', 'gmp', 'mpfr']
Optional-Dependencies	[]
Build-Dependencies	[]
Provides	[]
Builddate	04-07-2024 22:43:38
Architecture	x86_64
Distro-Version
Licenses	['LGPL-3.0-only']
Hash	10554706eb15ed2186fbd55fd5db8fa5919788ac9a75d26c0b9ef5bdfca9d470

# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>

pkgname=libmpc
pkgver=1.3.1
pkgrel=2
pkgdesc='Library for the arithmetic of complex numbers with arbitrarily high precision'
arch=(x86_64)
url='http://www.multiprecision.org/'
license=(LGPL-3.0-only)
depends=(glibc
         gmp
         mpfr)
source=(https://ftp.gnu.org/gnu/mpc/mpc-${pkgver/_/-}.tar.gz{,.sig})
sha256sums=('ab642492f5cf882b74aa0cb730cd410a81edcdbec895183ce930e706c1c759b8'
            'SKIP')
validpgpkeys=('AD17A21EF8AED8F1CC02DBD9F7D5C9BF765C61E3')  # Andreas Enge

build() {
  cd mpc-$pkgver
  ./configure \
    --prefix=/usr
  make
}

check() {
  cd mpc-$pkgver
  make check
}

package() {
  cd mpc-$pkgver
  make DESTDIR="$pkgdir" install
  mv "$pkgdir"/usr/share/info/{mpc,libmpc}.info
}