Name	libnghttp2
Description	Framing layer of HTTP/2 is implemented as a reusable C library
Version	1.68.0-1
Package Base	libnghttp2
Homepage	https://nghttp2.org/
Maintainers	['Anatol Pomozov', 'Christian Hesse <eworm@archlinux.org>']
Contributors	['Zhuoyun Wei <wzyboy@wzyboy.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libnghttp2
Sources	['git+https://github.com/mruby/mruby.git', 'git+https://github.com/nghttp2/nghttp2.git#tag=v1.68.0?signed', 'git+https://github.com/ngtcp2/munit.git', 'git+https://github.com/tatsuhiro-t/neverbleed.git']
Dependencies	['glibc']
Optional-Dependencies	[]
Build-Dependencies	['git']
Provides	['libnghttp2.so']
Builddate	26-10-2025 10:18:33
Architecture	x86_64
Distro-Version
Licenses	['MIT']
Hash	5069aca35ac522e8a7de7ddb2b4d6c62e4d6d05b7e19288b7de2c1e3d9d69d96

# Maintainer: Anatol Pomozov
# Contributor: Zhuoyun Wei <wzyboy@wzyboy.org>

pkgname=libnghttp2
pkgver=1.68.0
pkgrel=1
pkgdesc='Framing layer of HTTP/2 is implemented as a reusable C library'
arch=('x86_64')
url='https://nghttp2.org/'
license=('MIT')
depends=('glibc')
provides=('libnghttp2.so')
makedepends=('git')
conflicts=('nghttp2<1.20.0-2')
validpgpkeys=('F4F3B91474D1EB29889BD0EF7E8403D5D673C366') # Tatsuhiro Tsujikawa <tatsuhiro.t@gmail.com>
source=("git+https://github.com/nghttp2/nghttp2.git#tag=v${pkgver}?signed"
        'git+https://github.com/ngtcp2/munit.git'
        'git+https://github.com/mruby/mruby.git'
        'git+https://github.com/tatsuhiro-t/neverbleed.git')
sha512sums=('b2d32a22127b09fad755e195afe1cb6a466af46ea1b2ea24f1dbe1451623d715a7e46104474967623112b0b00c2fae05adc50dbab24f0862c2741880b309d20d'
            'SKIP'
            'SKIP'
            'SKIP')

prepare() {
  cd nghttp2

  git config --file=.gitmodules submodule.tests/munit.url ../munit/
  git config --file=.gitmodules submodule.third-party/mruby.url ../mruby/
  git config --file=.gitmodules submodule.tests/neverbleed.url ../neverbleed/

  git submodule init
  git -c protocol.file.allow=always submodule update

  autoreconf -i
}

build() {
  cd nghttp2

  ./configure \
    --prefix=/usr \
    --disable-examples \
    --disable-python-bindings \
    --enable-lib-only
  make
}

check() {
  cd nghttp2
  make check
}

package() {
  cd nghttp2/lib

  make DESTDIR="$pkgdir" install
  install -Dm644 ../COPYING "$pkgdir/usr/share/licenses/libnghttp2/COPYING"
}