Name	libnghttp3
Description	HTTP/3 library written in C
Version	1.15.0-1
Package Base	libnghttp3
Homepage	https://github.com/ngtcp2/nghttp3
Maintainers	['Christian Hesse <eworm@archlinux.org>', 'kpcyrd <kpcyrd[at]archlinux[dot]org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libnghttp3
Sources	['git+https://github.com/ngtcp2/munit.git', 'git+https://github.com/ngtcp2/nghttp3.git#tag=v1.15.0?signed', 'git+https://github.com/ngtcp2/sfparse.git']
Dependencies	['glibc']
Optional-Dependencies	[]
Build-Dependencies	['git']
Provides	['libnghttp3.so']
Builddate	20-01-2026 12:04:53
Architecture	x86_64
Distro-Version
Licenses	['MIT']
Hash	82e17219935617e3a33b8fc809199bcce666d705e7243799e5455404d598d4a7

# Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
# Maintainer: Christian Hesse <eworm@archlinux.org>

pkgname=libnghttp3
pkgver=1.15.0
pkgrel=1
pkgdesc='HTTP/3 library written in C'
url='https://github.com/ngtcp2/nghttp3'
arch=('x86_64')
license=('MIT')
depends=('glibc')
makedepends=('git')
provides=('libnghttp3.so')
validpgpkeys=('F4F3B91474D1EB29889BD0EF7E8403D5D673C366') # Tatsuhiro Tsujikawa <tatsuhiro.t@gmail.com>
source=("git+https://github.com/ngtcp2/nghttp3.git#tag=v${pkgver}?signed"
        'git+https://github.com/ngtcp2/munit.git'
        'git+https://github.com/ngtcp2/sfparse.git')
sha256sums=('490ce6f743bd9515351020a1182d7e220879ce40ee695d0b019a10eb3a7359bc'
            'SKIP'
            'SKIP')

prepare() {
  cd nghttp3/

  git config --file=.gitmodules submodule.tests/munit.url ../munit/
  git config --file=.gitmodules submodule.lib/sfparse.url ../sfparse/

  git submodule init
  git -c protocol.file.allow=always submodule update

  autoreconf -i
}

build() {
  cd nghttp3/

  ./configure \
    --prefix=/usr
  make
}

check() {
  cd nghttp3/

  make check
}

package() {
  cd nghttp3/

  make DESTDIR="${pkgdir}" install
  install -D -m0644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}