Name	libngtcp2
Description	Implementation of IETF QUIC protocol
Version	1.20.0-1
Package Base	libngtcp2
Homepage	https://github.com/ngtcp2/ngtcp2
Maintainers	['Christian Hesse <eworm@archlinux.org>', 'kpcyrd <kpcyrd[at]archlinux[dot]org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libngtcp2
Sources	['git+https://github.com/ngtcp2/munit.git', 'git+https://github.com/ngtcp2/ngtcp2.git#tag=v1.20.0?signed', 'git+https://github.com/ngtcp2/urlparse.git']
Dependencies	['glibc', 'gnutls', 'libssl.so', 'openssl']
Optional-Dependencies	[]
Build-Dependencies	['git', 'brotli']
Provides	['libngtcp2.so', 'libngtcp2_crypto_gnutls.so', 'libngtcp2_crypto_ossl.so']
Builddate	20-01-2026 12:05:41
Architecture	x86_64
Distro-Version
Licenses	['MIT']
Hash	7633b761d3cdf6e4fb205b1acc443f9be01107f6d081a65b2200bd755c39be50

# Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>

pkgname=libngtcp2
pkgver=1.20.0
pkgrel=1
pkgdesc='Implementation of IETF QUIC protocol'
url='https://github.com/ngtcp2/ngtcp2'
arch=('x86_64')
license=('MIT')
depends=(
  'glibc'
  'openssl' 'libssl.so'
  'gnutls'
)
makedepends=(
  'git'
  'brotli'
)
provides=(
  'libngtcp2.so'
  'libngtcp2_crypto_gnutls.so'
  'libngtcp2_crypto_ossl.so'
)
validpgpkeys=('F4F3B91474D1EB29889BD0EF7E8403D5D673C366') # Tatsuhiro Tsujikawa <tatsuhiro.t@gmail.com>
source=("git+https://github.com/ngtcp2/ngtcp2.git#tag=v${pkgver}?signed"
        'git+https://github.com/ngtcp2/munit.git'
        'git+https://github.com/ngtcp2/urlparse.git')
sha256sums=('a2ecedfcb7c859fa699f6bd84afac3f71568a73a8dbc7e84f4213a533e4464ff'
            'SKIP'
            'SKIP')
b2sums=('09390fc9dc1fa54be684e89f67f5049eb9c728c94e8dc1161be6dc1c1b42d941d0e10d62e1b54459f9f46ec7d2bc818afc0aed97ec74b32a0a14c59d73ef80c9'
        'SKIP'
        'SKIP')

prepare() {
  cd ngtcp2/

  git config --file=.gitmodules submodule.tests/munit.url ../munit/
  git config --file=.gitmodules submodule.third-party/urlparse.url ../urlparse/

  git submodule init
  git -c protocol.file.allow=always submodule update

  autoreconf -i
}

build() {
  cd ngtcp2/

  ./configure \
    --prefix=/usr \
    --with-libbrotlienc \
    --with-libbrotlidec \
    --with-gnutls \
    --enable-lib-only
  make
}

package() {
  cd ngtcp2/

  make DESTDIR="${pkgdir}" install
  install -D -m0644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}