Name	libnl
Description	Library for applications dealing with netlink sockets
Version	3.12.0-1
Package Base	libnl
Homepage	https://github.com/thom311/libnl/
Maintainers	['Bartłomiej Piotrowski <bpiotrowski@archlinux.org>', 'Christian Hesse <eworm@archlinux.org>']
Contributors	['Thomas Bächler <thomas@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libnl
Sources	['git+https://github.com/thom311/libnl.git#tag=libnl3_12_0?signed']
Dependencies	['gcc-libs', 'glibc']
Optional-Dependencies	[]
Build-Dependencies	['git']
Provides	['libnl-3.so', 'libnl-cli-3.so', 'libnl-genl-3.so', 'libnl-idiag-3.so', 'libnl-nf-3.so', 'libnl-route-3.so', 'libnl-xfrm-3.so']
Builddate	05-12-2025 11:09:57
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.1-only']
Hash	531827dac4f6d3de9a7e4c8c31f3243bf484b39c41648178c18dc027566b1bb4

# Maintainer:  Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Thomas Bächler <thomas@archlinux.org>

pkgname=libnl
pkgver=3.12.0
pkgrel=1
pkgdesc='Library for applications dealing with netlink sockets'
arch=('x86_64')
url='https://github.com/thom311/libnl/'
license=('LGPL-2.1-only')
depends=('glibc'
         'libgcc' 'libgcc_s.so')
makedepends=('git')
provides=('libnl-3.so' 'libnl-cli-3.so' 'libnl-genl-3.so' 'libnl-idiag-3.so'
          'libnl-nf-3.so' 'libnl-route-3.so' 'libnl-xfrm-3.so')
backup=('etc/libnl/classid'
        'etc/libnl/pktloc')
validpgpkeys=('49EA7C670E0850E7419514F629C2366E4DFC5728'  # Thomas Haller <thaller@redhat.com>
              '67DA3FAEBAE276BA58FC6CE314F18A98993AECD5') # Thomas Haller <thom311@gmail.com>
source=("git+https://github.com/thom311/libnl.git#tag=libnl${pkgver//./_}?signed")
sha256sums=('d741b8f94ef4a64b953603efce660a2eec4eb0cb6cd7faeabf75c8af99f0bcab')

prepare() {
  cd "${pkgname}"
  ./autogen.sh
}

build() {
  cd "${pkgname}"
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --sbindir=/usr/bin \
    --disable-static
  make
}

check() {
  make -C "${pkgname}" check
}

package() {
  make -C "${pkgname}" DESTDIR="${pkgdir}" install
}