Name	libnotify
Description	Library for sending desktop notifications
Version	0.8.8-1
Package Base	libnotify
Homepage	https://gitlab.gnome.org/GNOME/libnotify
Maintainers	['Jan Alexander Steffens (heftig) <heftig@archlinux.org>']
Contributors	['Jan de Groot <jgc@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libnotify
Sources	['git+https://gitlab.gnome.org/GNOME/libnotify.git?signed#tag=0.8.8']
Dependencies	['gcc-libs', 'gdk-pixbuf2', 'glib2', 'glibc']
Optional-Dependencies	[]
Build-Dependencies	['docbook-xsl', 'gi-docgen', 'git', 'glib2-devel', 'gobject-introspection', 'meson', 'xmlto']
Provides	['libnotify.so']
Builddate	09-01-2026 21:30:52
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.1-or-later']
Hash	57e117e47e271e491e929ee3c6d1449d5fe334830e1d0742d458d02554f8c9ab

# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>

pkgbase=libnotify
pkgname=(
  libnotify
  libnotify-docs
)
pkgver=0.8.8
pkgrel=1
pkgdesc="Library for sending desktop notifications"
url="https://gitlab.gnome.org/GNOME/libnotify"
arch=(x86_64)
license=(LGPL-2.1-or-later)
depends=(
  gcc-libs
  gdk-pixbuf2
  glib2
  glibc
)
makedepends=(
  docbook-xsl
  gi-docgen
  git
  glib2-devel
  gobject-introspection
  meson
  xmlto
)
checkdepends=(
  dbus
  gtk4
  python-dbusmock
  python-gobject
  xorg-server-xvfb
)
source=("git+$url.git?signed#tag=$pkgver")
b2sums=('47ef6c21881ccd8390f4f226abcb55b685f2a9dfa0aa0fe554c2e39d11deffe36f17eb2c04b9ee5d8e5900f2bb9e646adc8405dc6631e47876878f53e3ce1a2c')
validpgpkeys=(
  98FF7532A4639119B8FB4F15E520923A38618D6C # Logan Rathbone (GNOME) <larathbone@gnome.org>
  D4C501DA48EB797A081750939449C2F50996635F # Marco Trevisan (Treviño) <mail@3v1n0.net>
)

prepare() {
  cd libnotify

  # Use external Xvfb
  sed -i "/xvfb_run, '-a'/d" tests/meson.build
}

build() {
  local meson_options=(
  )

  arch-meson libnotify build "${meson_options[@]}"
  meson compile -C build
}

check() {
  xvfb-run -s '-nolisten local' meson test -C build --print-errorlogs
}

package_libnotify() {
  provides=(libnotify.so)

  meson install -C build --destdir "$pkgdir"

  mkdir -p doc/usr/share
  mv {"$pkgdir",doc}/usr/share/doc
}

package_libnotify-docs() {
  pkgdesc+=" (documentation)"
  depends=()

  mv doc/* "$pkgdir"
}

# vim:set sw=2 sts=-1 et: