Name	libogg
Description	Ogg bitstream and framing library
Version	1.3.6-1
Package Base	libogg
Homepage	https://www.xiph.org/ogg/
Maintainers	['Maxime Gauduin <alucryd@archlinux.org>', 'T.J. Townsend <blakkheim@archlinux.org>']
Contributors	['John Proctor <jproctor@prium.net>', 'Tom Gundersen <teg@jklm.no>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libogg
Sources	['git+https://github.com/xiph/ogg.git?signed#tag=v1.3.6']
Dependencies	['glibc']
Optional-Dependencies	[]
Build-Dependencies	['cmake', 'git', 'ninja']
Provides	['libogg.so']
Builddate	15-07-2025 00:57:33
Architecture	x86_64
Distro-Version
Licenses	['BSD']
Hash	b6d4724c1ed16b4806fa596cd823a2930efeeddeb95f7d8a869644b665a9ba37

# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Tom Gundersen <teg@jklm.no>
# Contributor: John Proctor <jproctor@prium.net>

pkgname=libogg
pkgver=1.3.6
pkgrel=1
pkgdesc='Ogg bitstream and framing library'
arch=(x86_64)
url=https://www.xiph.org/ogg/
license=(BSD)
depends=(glibc)
makedepends=(
  cmake
  git
  ninja
)
provides=(libogg.so)
source=(git+https://github.com/xiph/ogg.git?signed#tag=v${pkgver})
sha256sums=('2e83a0b16d3863e87f3d9372686b00fa0bf62a2641b458b929185103645fdf35')
validpgpkeys=(B7B00AEE1F960EEA0FED66FB9259A8F2D2D44C84) # Ralph Giles <giles@thaumas.net>

prepare() {
  cd ogg
}

build() {
  cmake -S ogg -B build -G Ninja \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DBUILD_SHARED_LIBS=ON
  cmake --build build
}

package() {
  DESTDIR="${pkgdir}" cmake --install build
  install -Dm 644 ogg/COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}/
  install -Dm 644 ogg/ogg.m4 -t "${pkgdir}"/usr/share/aclocal/
}

# vim: ts=2 sw=2 et: