Name	libopenmpt
Description	A library to render tracker music to a PCM audio stream
Version	0.8.4-1
Package Base	libopenmpt
Homepage	https://lib.openmpt.org/libopenmpt/
Maintainers	['David Runge <dvzrv@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libopenmpt
Sources	['libopenmpt-0.8.4.tar.gz::https://lib.openmpt.org/files/libopenmpt/src/libopenmpt-0.8.4+release.autotools.tar.gz']
Dependencies	['flac', 'gcc-libs', 'glibc', 'libogg', 'libpulse', 'libsndfile', 'libvorbis', 'mpg123', 'portaudio', 'zlib']
Optional-Dependencies	[]
Build-Dependencies	['autoconf-archive', 'doxygen', 'help2man']
Provides	['libopenmpt.so']
Builddate	21-12-2025 17:15:21
Architecture	x86_64
Distro-Version
Licenses	['BSD-3-Clause']
Hash	daa7a71ec409015f9fa3e3b544773c1d7a6ba6c99c89ab0968828c61c430b2f4

# Maintainer: David Runge <dvzrv@archlinux.org>

pkgname=libopenmpt
pkgver=0.8.4
pkgrel=1
pkgdesc="A library to render tracker music to a PCM audio stream"
arch=(x86_64)
url="https://lib.openmpt.org/libopenmpt/"
license=(BSD-3-Clause)
depends=(
  flac
  gcc-libs
  glibc
  libogg  # required by pkgconf
  libpulse
  libsndfile
  libvorbis
  mpg123
  portaudio
  zlib
)
makedepends=(
  autoconf-archive
  doxygen
  help2man
)
provides=(libopenmpt.so)
source=($pkgname-$pkgver.tar.gz::https://lib.openmpt.org/files/libopenmpt/src/$pkgname-$pkgver+release.autotools.tar.gz)
sha512sums=('23abe582996431a9129b7119e89bfda62d5f69427aa192081574e5fc4f491a63dccce3343b104cf005a402c4484cea4642e7856c156a19d41504e4f854d72af9')
b2sums=('0e7fa957e9e9ce16d478dee079cc368f320f268020f454380e9e0c968820669dcaeb05012d5fe857762132a01dd950fa637208d9e2a611f140434630164bbb89')

prepare() {
  cd $pkgname-$pkgver+release.autotools
  autoreconf -fiv
}

build() {
  cd $pkgname-$pkgver+release.autotools
  ./configure --prefix=/usr
  # prevent excessive overlinking due to libtool
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  make -k check -C $pkgname-$pkgver+release.autotools
}

package() {
  cd $pkgname-$pkgver+release.autotools
  make DESTDIR="$pkgdir" install
  install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}