Name	libpcap
Description	A system-independent interface for user-level packet capture
Version	1.10.6-1
Package Base	libpcap
Homepage	https://www.tcpdump.org/
Maintainers	['David Runge <dvzrv@archlinux.org>']
Contributors	['Bartłomiej Piotrowski <bpiotrowski@mirantis.com>', 'Thomas Bächler <thomas@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libpcap
Sources	['git+https://github.com/the-tcpdump-group/libpcap?signed#tag=libpcap-1.10.6']
Dependencies	['glibc', 'libdbus-1.so', 'libnl', 'sh']
Optional-Dependencies	[]
Build-Dependencies	['bluez-libs', 'dbus', 'git']
Provides	['libpcap.so']
Builddate	05-01-2026 13:47:55
Architecture	x86_64
Distro-Version
Licenses	['BSD-3-Clause']
Hash	a0ab9d77269182e4b734d68a14f74f2ab080171c5ce61b52166e02749667a898

# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@mirantis.com>
# Contributor: Thomas Bächler <thomas@archlinux.org>

pkgname=libpcap
pkgver=1.10.6
pkgrel=1
pkgdesc='A system-independent interface for user-level packet capture'
arch=(x86_64)
url='https://www.tcpdump.org/'
_url=https://github.com/the-tcpdump-group/libpcap
license=(BSD-3-Clause)
depends=(
  glibc
  libnl
  sh
)
makedepends=(
  bluez-libs
  dbus
  git
)
provides=(libpcap.so)
source=(git+$_url?signed#tag=$pkgname-$pkgver)
sha512sums=('2eefea34a799a8332460f1f367c9089c2392d1e1f4618553911e5905873c213b62c21c8f684d30c3a6d357ec58662faf2d7b9d8486196a5236feeec77f61b6de')
b2sums=('1a8c4cfe387b1636d121355e730ad373e53e995885a68756d9655ca99665fc82d1a9be63e81fe55395928bd22d1ced89a5eb77150d45659c91d6c976ce83a8c0')
validpgpkeys=('1F166A5742ABB9E0249A8D30E089DEF1D9C15D0D') # The Tcpdump Group

prepare() {
  cd $pkgname
  autoreconf -fiv
}

build() {
  local configure_options=(
    --prefix=/usr
    --enable-ipv6
    --enable-bluetooth
    --enable-usb
    --with-libnl
  )

  cd $pkgname
  ./configure "${configure_options[@]}"
  make
}

package() {
  depends+=(libdbus-1.so)

  cd $pkgname
  make DESTDIR="$pkgdir" install
  install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
  install -vDm 644 {CHANGES,{CONTRIBUTING,README}.md} -t "$pkgdir/usr/share/doc/$pkgname/"
}