Name	libpgm
Description	Library implementing the Pragmatic General Multicast (PGM, RFC3208) reliable transport protocol (OpenPGM)
Version	5.3.128-3
Package Base	libpgm
Homepage	https://github.com/steve-o/openpgm
Maintainers	['Balló György <ballogyor+arch@gmail.com>', 'Balló György <bgyorgy@archlinux.org>']
Contributors	['Kyle Keen <keenerd@gmail.com>', 'Lex Black <autumn-wind@web.de>', 'Vladimir Kirillov <proger@wilab.org.ua>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libpgm
Sources	['git+https://github.com/steve-o/openpgm.git#tag=release-5-3-128']
Dependencies	['glibc']
Optional-Dependencies	[]
Build-Dependencies	['git', 'python']
Provides	[]
Builddate	27-05-2023 23:48:12
Architecture	x86_64
Distro-Version
Licenses	['LGPL']
Hash	346a6d1a1b707595454875ae0487164e9947cff25b2eaf142ee7a2d6c5a6ec29

# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Kyle Keen <keenerd@gmail.com>
# Contributor: Lex Black <autumn-wind at web dot de>
# Contributor: Vladimir Kirillov <proger@wilab.org.ua>

pkgname=libpgm
pkgver=5.3.128
pkgrel=3
pkgdesc='Library implementing the Pragmatic General Multicast (PGM, RFC3208) reliable transport protocol (OpenPGM)'
arch=(x86_64)
url='https://github.com/steve-o/openpgm'
license=(LGPL-2.1-or-later)
depends=(glibc)
makedepends=(
  git
  python
)
source=("git+https://github.com/steve-o/openpgm.git#tag=release-${pkgver//./-}")
b2sums=(3718430386e4ca8b9e51dbd69a17d4bb71ef0169b8f78f66865aae3d5cca09f4bd63d18bac714b4e5a89ad09ecdb73a3fd8f7163c1806c0c1ff2f109a8898dcd)

prepare() {
  cd openpgm/openpgm/pgm

  # https://github.com/steve-o/openpgm/pull/66
  git cherry-pick -n 240634b1afb968a051f8c68696eae2a582a02450

  autoreconf -fi
}

build() {
  cd openpgm/openpgm/pgm
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var
  make
}

package() {
  cd openpgm/openpgm/pgm
  make DESTDIR="$pkgdir" install
}