Name	libpsl
Description	Public Suffix List library
Version	0.21.5-2
Package Base	libpsl
Homepage	https://github.com/rockdaboot/libpsl
Maintainers	['Levente Polyak <anthraxx@archlinux.org>', 'Levente Polyak <anthraxx[at]archlinux[dot]org>']
Contributors	['Darshit Shah <darnir@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libpsl
Sources	['https://github.com/rockdaboot/libpsl/releases/download/0.21.5/libpsl-0.21.5.tar.gz', 'https://github.com/rockdaboot/libpsl/releases/download/0.21.5/libpsl-0.21.5.tar.gz.sig']
Dependencies	['libidn2', 'libidn2.so', 'libunistring', 'libunistring.so']
Optional-Dependencies	[]
Build-Dependencies	['gtk-doc', 'libxslt', 'publicsuffix-list', 'python']
Provides	['libpsl.so']
Builddate	06-05-2024 20:19:53
Architecture	x86_64
Distro-Version
Licenses	['MIT']
Hash	e07925c2487bd7deffdd57808b19561e80a4cb25a33e51dbd94efb673bc81944

# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Darshit Shah <darnir@gmail.com>

pkgname=libpsl
pkgver=0.21.5
pkgrel=2
pkgdesc='Public Suffix List library'
url='https://github.com/rockdaboot/libpsl'
arch=('x86_64')
license=('MIT')
depends=(
  libidn2
  libunistring
)
makedepends=(
  gtk-doc
  libxslt
  publicsuffix-list
  python
)
provides=('libpsl.so')
source=(https://github.com/rockdaboot/libpsl/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.gz{,.sig})
sha512sums=('c14d575cecc0f1693894dd79565b6b9220084ddfa43b908a1cefe16d147cdd5ec47796eb0c2135e2f829a951abaf39d8a371ab5c1352f57b36e610e25adf91f5'
            'SKIP')
b2sums=('a0076f622b85df99f866de6707850ac216b764bdb68c6d516f4603da42dac8eae3ee4c53d68dbb6af6f779c2c7f1b9caab74c8b558209b1f6823f95c13fc3ceb'
        'SKIP')
validpgpkeys=('1CB27DBC98614B2D5841646D08302DB6A2670428') # Tim Rühsen <tim.ruehsen@gmx.de>

prepare() {
  cd ${pkgname}-${pkgver}
  rm -frv list
  autoreconf -fiv
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure \
    --prefix=/usr \
    --disable-static \
    --disable-dependency-tracking \
    --enable-man \
    --enable-gtk-doc \
    --enable-{builtin,runtime}=libidn2 \
    --with-psl-file=/usr/share/publicsuffix/effective_tld_names.dat \
    --with-psl-testfile=/usr/share/publicsuffix/test_psl.txt
  LC_CTYPE=en_US.UTF-8 make
}

check() {
  cd ${pkgname}-${pkgver}
  make check
}

package() {
  depends+=('libidn2.so' 'libunistring.so')

  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

# vim: ts=2 sw=2 et: