Name	libsamplerate
Description	An audio sample rate conversion library
Version	0.2.2-3
Package Base	libsamplerate
Homepage	https://libsndfile.github.io/libsamplerate/
Maintainers	['David Runge <dvzrv@archlinux.org>', 'T.J. Townsend <blakkheim@archlinux.org>']
Contributors	['Eric Bélanger <eric@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libsamplerate
Sources	['https://github.com/libsndfile/libsamplerate/releases/download/0.2.2/libsamplerate-0.2.2.tar.xz', 'https://github.com/libsndfile/libsamplerate/releases/download/0.2.2/libsamplerate-0.2.2.tar.xz.sig']
Dependencies	['glibc']
Optional-Dependencies	[]
Build-Dependencies	['alsa-lib', 'cmake', 'libsndfile', 'opus']
Provides	['libsamplerate.so']
Builddate	12-07-2024 23:13:25
Architecture	x86_64
Distro-Version
Licenses	['BSD']
Hash	6641b016f15c73f90ee0741f0d14db1ea7ec988a2b8c74c5fce0182239bbbf00

# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: Eric Bélanger <eric@archlinux.org>

pkgname=libsamplerate
pkgver=0.2.2
pkgrel=3
pkgdesc="An audio sample rate conversion library"
arch=(x86_64)
url="https://libsndfile.github.io/libsamplerate/"
license=(BSD)
depends=(glibc)
makedepends=(alsa-lib cmake libsndfile opus)
checkdepends=(fftw)
provides=(libsamplerate.so)
source=(https://github.com/libsndfile/$pkgname/releases/download/$pkgver/$pkgname-$pkgver.tar.xz{,.sig})
sha512sums=('d23ae54d23209ba22baae9e5fd178dd8e0e99205dada7e7c3a7b3a3d8cf816ed427a411bfeb008427f64da7767d645edce40811f238af11c8c386f5ef25a9f0c'
            'SKIP')
b2sums=('71b1e8a1644a94fff019abc6bf98c557df84994293f1e9bc651ad3ad3f0afeb24f54b8c75fc26e5202ae7c3a3e34e783fd1be7f7c6fdefe9eac9a5dfe7100b91'
        'SKIP')
validpgpkeys=('31D95CAB6D80D262244A1750A47620E801E47E95')  # David Seifert soap@gentoo.org

build() {
  local cmake_options=(
    -B build
    -D CMAKE_INSTALL_PREFIX=/usr
    -D CMAKE_BUILD_TYPE=None
    -D CMAKE_POLICY_VERSION_MINIMUM=3.5
    -D BUILD_SHARED_LIBS=ON
    -S $pkgname-$pkgver
    -Wno-dev
  )

  cmake "${cmake_options[@]}"
  cmake --build build --verbose
}

check() {
  ctest --test-dir build --output-on-failure
}

package() {
  DESTDIR="$pkgdir" cmake --install build
  install -vDm 644 $pkgname-$pkgver/{AUTHORS,NEWS,README.md,ChangeLog} -t "$pkgdir/usr/share/doc/$pkgname/"
  install -vDm 644 $pkgname-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
}