Name	libssh
Description	Library for accessing ssh client services through C libraries
Version	0.12.0-1
Package Base	libssh
Homepage	https://www.libssh.org/
Maintainers	['Antonio Rojas <arojas@archlinux.org>']
Contributors	['Andrea Scarpino <andrea@archlinux.org>', 'Tom Gundersen <teg@jklm.no>', 'ice-man <icemanf@gmail.com>', 'sergeantspoon <sergeantspoon@archlinux.us>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libssh
Sources	['https://www.libssh.org/files/0.12/libssh-0.12.0.tar.xz', 'https://www.libssh.org/files/0.12/libssh-0.12.0.tar.xz.asc']
Dependencies	['glibc', 'openssl', 'zlib']
Optional-Dependencies	[]
Build-Dependencies	['cmake', 'cmocka', 'doxygen', 'openssh', 'python']
Provides	['libssh.so']
Builddate	10-02-2026 13:28:57
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.1-or-later']
Hash	1e488cfd5e31a10b7c0c5e61c31efda5151f215664b3a28caf41226bda02b004

# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Tom Gundersen <teg@jklm.no>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: ice-man <icemanf@gmail.com>
# Contributor: sergeantspoon <sergeantspoon@archlinux.us>

pkgbase=libssh
pkgname=(libssh
         libssh-docs)
pkgver=0.12.0
pkgrel=1
pkgdesc='Library for accessing ssh client services through C libraries'
url='https://www.libssh.org/'
license=('LGPL-2.1-or-later')
arch=(x86_64)
depends=(glibc
         openssl
         zlib)
makedepends=(cmake
             cmocka
             doxygen
             openssh
             python)
provides=(libssh.so)
source=("https://www.libssh.org/files/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz"{,.asc})
sha256sums=('1a6af424d8327e5eedef4e5fe7f5b924226dd617ac9f3de80f217d82a36a7121'
            'SKIP')
validpgpkeys=('8DFF53E18F2ABC8D8F3C92237EE0FC4DCC014E3D'  # Andreas Schneider <asn@cryptomilk.org>
              '88A228D89B07C2C77D0C780903D5DF8CFDD3E8E7') # libssh release key (release key) <libssh@libssh.org>

build() {
  cmake \
    -B build \
    -S $pkgname-$pkgver \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DWITH_GSSAPI=OFF \
    -DUNIT_TESTING=ON
  cmake --build build
  cmake --build build --target docs
}

check() {
  cmake --build build --target test
}

package_libssh() {
  DESTDIR="$pkgdir" cmake --install build
}

package_libssh-docs() {
  pkgdesc='Documentation for libssh'
  depends=()
  provides=()

  mkdir -p "$pkgdir"/usr/share/doc/libssh
  cp -r build/doc/html "$pkgdir"/usr/share/doc/libssh
#  cp -r build/doc/man "$pkgdir"/usr/share
#  rm "$pkgdir"/usr/share/man/man3/{bug,deprecated}.*
}