Name	libssh2
Description	A library implementing the SSH2 protocol as defined by Internet Drafts
Version	1.11.1-1
Package Base	libssh2
Homepage	https://www.libssh2.org/
Maintainers	['Felix Yan <felixonmars@archlinux.org>', 'Tobias Powalowski <tpowa@archlinux.org>']
Contributors	['Andrea Scarpino <andrea@archlinux.org>', 'Angel Velasquez <angvp@archlinux.org>', 'Dave Reisner <dreisner@archlinux.org>', 'Sergej Pupykin <pupykin.s+arch@gmail.com>', 'ice-man <icemanf@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libssh2
Sources	['https://www.libssh2.org/download/libssh2-1.11.1.tar.gz', 'https://www.libssh2.org/download/libssh2-1.11.1.tar.gz.asc']
Dependencies	['openssl', 'zlib']
Optional-Dependencies	[]
Build-Dependencies	[]
Provides	['libssh2.so']
Builddate	01-01-2025 16:56:10
Architecture	x86_64
Distro-Version
Licenses	['BSD']
Hash	c13dba4c4786918ec25f4ccdf1c4567c8063a4caae8565c2a241488584621bad

# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Dave Reisner <dreisner@archlinux.org>
# Contributor: Angel Velasquez <angvp@archlinux.org>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: ice-man <icemanf@gmail.com>

pkgname=libssh2
pkgver=1.11.1
pkgrel=1
pkgdesc="A library implementing the SSH2 protocol as defined by Internet Drafts"
url="https://www.libssh2.org/"
arch=('x86_64')
license=('BSD')
depends=('openssl' 'zlib')
provides=('libssh2.so')
validpgpkeys=('27EDEAF22F3ABCEB50DB9A125CC908FDB71E12C2'   # Daniel Stenberg
              '914C533DF9B2ADA2204F586D78E11C6B279D5C91')  # Daniel Stenberg (old key)
source=("https://www.libssh2.org/download/$pkgname-$pkgver.tar.gz"{,.asc})
b2sums=('a44073d59eeeed57626063067d498f28d64f66febf5cdbd830cf1fa0ffd33e39f4bca57289abef175d4f0413952e1dbc57847aa4fe1d9c0140d8789b7b925528'
        'SKIP')

build() {
  cd "$pkgname-$pkgver"

  ./configure --prefix=/usr --disable-docker-tests
  make
}

check() {
  make -C "$pkgname-$pkgver" check
}

package() {
  cd "$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}