Name	libunwind
Description	Determine and manipulate the call-chain of a program
Version	1.8.2-1
Package Base	libunwind
Homepage	https://www.nongnu.org/libunwind/
Maintainers	['Antonio Rojas <arojas@archlinux.org>', 'Felix Yan <felixonmars@archlinux.org>']
Contributors	['Lawrence Lee <valheru@facticius.net>', 'Phillip Marvin <phillip.marvin@gmail.com>', 'Sébastien Luttringer', 'keystone <phillip.marvin@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libunwind
Sources	['https://github.com/libunwind/libunwind/commit/b67d508a.patch', 'https://github.com/libunwind/libunwind/releases/download/v1.8.2/libunwind-1.8.2.tar.gz', 'https://github.com/libunwind/libunwind/releases/download/v1.8.2/libunwind-1.8.2.tar.gz.asc']
Dependencies	['glibc', 'xz', 'zlib']
Optional-Dependencies	[]
Build-Dependencies	['texlive-binextra']
Provides	['libunwind-coredump.so', 'libunwind-ptrace.so', 'libunwind-setjmp.so', 'libunwind-x86_64.so', 'libunwind.so']
Builddate	28-06-2025 00:55:58
Architecture	x86_64
Distro-Version
Licenses	['MIT']
Hash	74ba64398637c2dad73f0ed09cee63a83a0f9a67f1484e6fea5a6223ff165d55

# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Sébastien Luttringer
# Contributor: Lawrence Lee <valheru@facticius.net>
# Contributor: Phillip Marvin <phillip.marvin@gmail.com>
# Contributor: keystone <phillip.marvin@gmail.com>

pkgname=libunwind
pkgver=1.8.2
pkgrel=1
pkgdesc="Determine and manipulate the call-chain of a program"
url="https://www.nongnu.org/libunwind/"
arch=(x86_64)
license=(MIT)
depends=(
  glibc
  xz
  zlib
)
makedepends=(texlive-binextra)
provides=(
  libunwind-{coredump,ptrace,setjmp,x86_64}.so
  libunwind.so
)
source=(
  https://github.com/libunwind/libunwind/releases/download/v$pkgver/libunwind-$pkgver.tar.gz{,.asc}
  https://github.com/libunwind/libunwind/commit/b67d508a.patch
)
b2sums=('b198b186c616adf1302d153a12949ceab07608f8133e42454e6b10bdf9518a514ef15d5ba52ef75b11e5f73fa330205accd415cfc30e6fa3ddd9724cbb088737'
        'SKIP'
        '756ced55c34a33d55cc11f61c32230de820aede55d562aa94143c2f5adb7f408ed2f2d5c48642b035ec4d3ebc59175e6f4b889f712db2556b80a8002d91aa036')
validpgpkeys=(
  F86EB09F72717426F20D36470A0FF845B7DB3427  # Stephen M. Webb <stephen.webb@bregmasoft.ca>
)

prepare() {
  cd libunwind-$pkgver
  patch -p1 -i ../b67d508a.patch # Fix build with GCC 15
  autoreconf -fvi
}

build() {
  local configure_options=(
    --prefix=/usr
    --sysconfdir=/etc
    --localstatedir=/var
  )

  cd libunwind-$pkgver
  ./configure "${configure_options[@]}"
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd libunwind-$pkgver
  make check
}

package() {
  cd libunwind-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm 644 COPYING -t "$pkgdir"/usr/share/licenses/$pkgname
  rm -r "$pkgdir"/usr/libexec
}

# vim:set sw=2 sts=-1 et: