Name	liburing
Description	Linux-native io_uring I/O access library
Version	2.14-1
Package Base	liburing
Homepage	https://github.com/axboe/liburing
Maintainers	['Christian Heusel <gromit@archlinux.org>', 'David Runge <dvzrv@archlinux.org>']
Contributors	['Filipe Laíns (FFY00) <lains@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/liburing
Sources	['git+https://github.com/axboe/liburing.git?signed#tag=liburing-2.14']
Dependencies	[]
Optional-Dependencies	[]
Build-Dependencies	['git']
Provides	['liburing.so', 'liburing-ffi.so']
Builddate	09-02-2026 01:04:14
Architecture	x86_64
Distro-Version
Licenses	['GPL-2.0-only WITH Linux-syscall-note OR MIT', 'LGPL-2.0-or-later', 'MIT']
Hash	6561dc39a66c2d4838dcaecfb693f8ae0ee4cfde8afc5511255f3986b9921202

# Maintainer: Christian Heusel <gromit@archlinux.org>
# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: Filipe Laíns (FFY00) <lains@archlinux.org>

pkgname=liburing
pkgver=2.14
pkgrel=1
pkgdesc="Linux-native io_uring I/O access library"
arch=(x86_64)
url="https://github.com/axboe/liburing"
license=(
  'GPL-2.0-only WITH Linux-syscall-note OR MIT'
  LGPL-2.0-or-later
  MIT
)
makedepends=(git)
provides=(
  liburing.so
  liburing-ffi.so
)
source=("git+https://github.com/axboe/liburing.git?signed#tag=$pkgname-$pkgver")
sha512sums=('5257cdc64e57c549814f136ebcd0850d531159cfc6832241f857dcc74bf717e1f8c2b6252b9a59d3228685cb0b2cc52632d54bf1e3b04331099a80bc9110fe8b')
b2sums=('cd1f572ba8ad27c4fbf5333f4585e593bb69d7ae6bde18b2dc1756882d2d6b09a2ac2056992db3c9bbb7538c4a417b50e5b7e9628f326bbd04eb649fbd284614')
validpgpkeys=(C0FC392DCADE26D975FA5E4AF7D358FB2971E0A6)  # Jens Axboe <axboe@kernel.dk>

build() {
  local configure_options=(
    --prefix=/usr
    --mandir=/usr/share/man
  )

  cd $pkgname
  ./configure "${configure_options[@]}"
  make
}

package() {
  make DESTDIR="$pkgdir" install -C $pkgname
  install -vDm 644 $pkgname/LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}