Name	libva-intel-driver
Description	VA-API implementation for Intel G45 and HD Graphics family
Version	2.4.1-5
Package Base	libva-intel-driver
Homepage	https://01.org/linuxmedia/vaapi
Maintainers	['Maxime Gauduin <alucryd@archlinux.org>']
Contributors	['Bartłomiej Piotrowski <bpiotrowski@archlinux.org>', 'Ionut Biru <ibiru@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libva-intel-driver
Sources	['git+https://github.com/intel/intel-vaapi-driver.git#tag=9a1f0c64174f970a26380d4957583c71372fbb7c']
Dependencies	['libdrm', 'libva']
Optional-Dependencies	[]
Build-Dependencies	['git', 'meson']
Provides	[]
Builddate	21-04-2025 15:55:08
Architecture	x86_64
Distro-Version
Licenses	['MIT']
Hash	b51857fff0d31b319941ae6982d080c29123693d5ea5a76e4decd5fe2c7d214a

# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>

pkgname=libva-intel-driver
pkgver=2.4.1
pkgrel=5
pkgdesc='VA-API implementation for Intel G45 and HD Graphics family'
arch=(x86_64)
url=https://01.org/linuxmedia/vaapi
license=(MIT)
depends=(
  libva
  libdrm
)
makedepends=(
  git
  meson
)
replaces=(libva-driver-intel)
_tag=4206d0e15363d188f30f2f3dbcc212fef206fc1d
source=(git+https://github.com/intel/intel-vaapi-driver.git#tag=9a1f0c64174f970a26380d4957583c71372fbb7c)
b2sums=('524369c3ced5b7d61bb93558bf95d6ef4f7af8c41362b1821f4f9d1c8887eb6bdde5549c98c8419bcd4fc1d5e042e564037f951ce9abaa30871eac7df863458f')

pkgver() {
  cd intel-vaapi-driver

  git describe --tags
}

prepare() {
  cd intel-vaapi-driver
  git cherry-pick -n 4206d0e15363d188f30f2f3dbcc212fef206fc1d
  # Only relevant if intel-gpu-tools is installed, since then the shaders will be recompiled
  sed -i '1s/python$/&2/' src/shaders/gpp.py
}

build() {
  CFLAGS+=' -fcommon' # https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common
  arch-meson intel-vaapi-driver build
  ninja -C build
}

package() {
  DESTDIR="${pkgdir}" meson install -C build
  install -Dm 644 intel-vaapi-driver/COPYING -t "${pkgdir}"/usr/share/licenses/libva-intel-driver
}

# vim: ts=2 sw=2 et: