Name	libva
Description	Video Acceleration (VA) API for Linux
Version	2.22.0-1
Package Base	libva
Homepage	https://01.org/linuxmedia/vaapi
Maintainers	['Maxime Gauduin <alucryd@archlinux.org>']
Contributors	['Bartłomiej Piotrowski <bpiotrowski@archlinux.org>', 'Ionut Biru <ibiru@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libva
Sources	['git+https://github.com/intel/libva.git#tag=217da1c28336d6a7e9c0c4cb8f1c303968a675f1']
Dependencies	['libdrm', 'libgl', 'libx11', 'libxext', 'libxfixes', 'wayland']
Optional-Dependencies	['intel-media-driver', 'libva-intel-driver', 'libva-mesa-driver']
Build-Dependencies	['git', 'libglvnd', 'mesa', 'meson']
Provides	['libva-drm.so', 'libva-glx.so', 'libva-wayland.so', 'libva-x11.so', 'libva.so']
Builddate	20-06-2024 17:59:14
Architecture	x86_64
Distro-Version
Licenses	['MIT']
Hash	ad3083a252bbac119d405ebeea7d86f9fc8e79cc27759303300e55ac9f6ffbda

# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>

pkgname=libva
pkgver=2.22.0
pkgrel=1
pkgdesc='Video Acceleration (VA) API for Linux'
arch=(x86_64)
url=https://01.org/linuxmedia/vaapi
license=(MIT)
depends=(
  libdrm
  libgl
  libx11
  libxext
  libxfixes
  wayland
)
makedepends=(
  git
  libglvnd
  mesa
  meson
)
optdepends=(
  'intel-media-driver: backend for Intel GPUs (>= Broadwell)'
  'libva-intel-driver: backend for Intel GPUs (<= Haswell)'
  'libva-mesa-driver: backend for AMD and NVIDIA GPUs'
)
provides=(
  libva-drm.so
  libva-glx.so
  libva-wayland.so
  libva-x11.so
  libva.so
)
backup=(etc/libva.conf)
_tag=217da1c28336d6a7e9c0c4cb8f1c303968a675f1
source=(git+https://github.com/intel/libva.git#tag=${_tag})
b2sums=('91289a53ca253fab3cfafaa45e42bff58a9cc84a2deb2db040ce693c6f64785eeddceea41018ce0e0e35a3447cac9582f8a68499432a7e384f95ef98e118d7e9')

pkgver() {
  cd libva
  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}

build() {
  CFLAGS+=" -DENABLE_VA_MESSAGING" # Option missing
  arch-meson libva build
  meson compile -C build
}

package() {
  meson install -C build --destdir "${pkgdir}"
  install -Dm 644 libva/COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
  install -Dm 644 /dev/stdin "${pkgdir}"/etc/libva.conf <<END
LIBVA_MESSAGING_LEVEL=1
END
}

# vim:set sw=2 sts=-1 et: