Name	libverto
Description	Main event loop abstraction library
Version	0.3.2-5
Package Base	libverto
Homepage	https://github.com/latchset/libverto
Maintainers	['Andreas Radke <andyrtr@archlinux.org>']
Contributors	['Mantas Mikulėnas <grawity@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libverto
Sources	['https://github.com/latchset/libverto/releases/download/0.3.2/libverto-0.3.2.tar.gz']
Dependencies	['glibc', 'libevent']
Optional-Dependencies	[]
Build-Dependencies	[]
Provides	['libverto.so', 'libverto-libevent.so', 'libverto-module-base']
Builddate	17-03-2024 10:03:10
Architecture	x86_64
Distro-Version
Licenses	['MIT']
Hash	1bbd5c0a3c21d7c48af1f1da687f65871c915e5fbbed50b2f02e6164fb0033cd

# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Mantas Mikulėnas <grawity@gmail.com>

pkgname=libverto
pkgver=0.3.2
pkgrel=5
pkgdesc="Main event loop abstraction library"
arch=('x86_64')
url="https://github.com/latchset/libverto"
license=('MIT')
depends=('glibc' 'libevent')
provides=('libverto.so' 'libverto-libevent.so' 'libverto-module-base')
conflicts=("krb5<1.19.3-2" "libverto-libevent<0.3.2-4")
replaces=("libverto-libevent<0.3.2-4")
source=("https://github.com/latchset/libverto/releases/download/$pkgver/libverto-$pkgver.tar.gz")
sha256sums=('8d1756fd704f147549f606cd987050fb94b0b1ff621ea6aa4d6bf0b74450468a')

build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr \
    --disable-static \
    --with-libevent \
    --without-libev \
    --without-glib
  make
}

check() {
  cd "$pkgname-$pkgver"
  make check
}

package_libverto() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install

  install -Dm0644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}