Name	libvpx
Description	VP8 and VP9 codec
Version	1.15.2-3
Package Base	libvpx
Homepage	https://www.webmproject.org/
Maintainers	['Lukas Fleischer <lfleischer@archlinux.org>', 'Maxime Gauduin <alucryd@archlinux.org>']
Contributors	['Bartłomiej Piotrowski <bpiotrowski@archlinux.org>', 'Ionut Biru <ibiru@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libvpx
Sources	['git+https://chromium.googlesource.com/webm/libvpx#tag=9aec918bf47611de2ffc7df61624c3d1b58be4ec']
Dependencies	['gcc-libs', 'glibc']
Optional-Dependencies	[]
Build-Dependencies	['git', 'nasm']
Provides	['libvpx.so']
Builddate	20-02-2026 16:21:22
Architecture	x86_64
Distro-Version
Licenses	['custom:BSD']
Hash	587a7d76956eb84e34fda9723cf02197c422573342a80e86c9a42f54066576e5

# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>

pkgname=libvpx
pkgver=1.15.2
pkgrel=3
pkgdesc='VP8 and VP9 codec'
arch=(x86_64)
url=https://www.webmproject.org/
license=(custom:BSD)
depends=(
  gcc-libs
  glibc
)
makedepends=(
  git
  nasm
)
provides=(libvpx.so)
_tag=9aec918bf47611de2ffc7df61624c3d1b58be4ec
source=(git+https://chromium.googlesource.com/webm/libvpx#tag=${_tag})
b2sums=('7dac94f25867bf023b5d15662996f867e435533b038da881352730b88f8fc9ae657c45b17c135579c3e4bd4039f450cb4f7e5e3e3f2738c68e230f901f7c6456')

pkgver() {
  cd libvpx
  git describe --tags | sed 's/^v//'
}

prepare() {
  cd libvpx

  # Backport fix for CVE-2026-1861
  git cherry-pick -n d5f35ac8d93cba7f7a3f7ddb8f9dc8bd28f785e1
}

build() {
  cd libvpx
  ./configure \
    --prefix=/usr \
    --disable-install-docs \
    --disable-install-srcs \
    --disable-unit-tests \
    --enable-pic \
    --enable-postproc \
    --enable-runtime-cpu-detect \
    --enable-shared \
    --enable-vp8 \
    --enable-vp9 \
    --enable-vp9-highbitdepth \
    --enable-vp9-temporal-denoising
  make
}

package() {
  cd libvpx
  make DIST_DIR="${pkgdir}"/usr install
  install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/libvpx/
}

# vim:set sw=2 sts=-1 et: