Name	libwacom
Description	Library to identify Wacom tablets and their features
Version	2.18.0-2
Package Base	libwacom
Homepage	https://github.com/linuxwacom/libwacom/wiki
Maintainers	['Andreas Radke <andyrtr@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libwacom
Sources	['https://github.com/linuxwacom/libwacom/releases/download/libwacom-2.18.0/libwacom-2.18.0.tar.xz', 'https://github.com/linuxwacom/libwacom/releases/download/libwacom-2.18.0/libwacom-2.18.0.tar.xz.sig']
Dependencies	['glib2', 'glibc', 'libevdev', 'libgcc', 'libgudev']
Optional-Dependencies	['python-libevdev', 'python-pyudev']
Build-Dependencies	['libxml2', 'meson', 'python-pytest', 'python-libevdev', 'python-pyudev']
Provides	[]
Builddate	14-02-2026 13:00:36
Architecture	x86_64
Distro-Version
Licenses	['MIT']
Hash	1d9fff9093aa29a8bd8d41263d19940e7af75cc98cf1b44577ae1bef9bfb260e

# Maintainer: Andreas Radke <andyrtr@archlinux.org>

pkgname=libwacom
pkgver=2.18.0
pkgrel=2
pkgdesc="Library to identify Wacom tablets and their features"
arch=('x86_64')
url="https://github.com/linuxwacom/libwacom/wiki"
license=('MIT')
depends=('glib2' 'libevdev' 'libgudev' 'glibc' 'libgcc')
makedepends=('libxml2' 'meson' 'python-pytest' 'python-libevdev' 'python-pyudev')
optdepends=('python-libevdev: for libwacom-show-stylus'
            'python-pyudev: for libwacom-show-stylus')
source=(https://github.com/linuxwacom/libwacom/releases/download/${pkgname}-${pkgver}/${pkgname}-${pkgver}.tar.xz{,.sig})
# https://github.com/linuxwacom/libwacom/releases
sha256sums=('7dbb9ab37df9df47ae2fdbb644916c986728291749bcd5ad8bcaa26f1e15f002'
            'SKIP')
validpgpkeys=('3C2C43D9447D5938EF4551EBE23B7E70B467F0BF') # "Peter Hutterer (Who-T) <office@who-t.net>"
#validpgpkeys=('594ABBA066118C7A02D10A80A8AF906D9307FBAD') # "Joshua Dickens <Joshua@Joshua-Dickens.com>"

build() {
  arch-meson $pkgname-$pkgver build
  # Print config
  meson configure build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"
  install -D -m644 $pkgname-$pkgver/COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}