Name	libwmf
Description	A library for reading vector images in Microsoft's native Windows Metafile Format (WMF)
Version	0.2.13-4
Package Base	libwmf
Homepage	https://github.com/caolanm/libwmf
Maintainers	['Carl Smedstad <carsme@archlinux.org>']
Contributors	['Eric Bélanger <eric@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libwmf
Sources	['libwmf-0.2.13.tar.gz::https://github.com/caolanm/libwmf/archive/v0.2.13.tar.gz']
Dependencies	['expat', 'freetype2', 'glibc', 'libjpeg-turbo', 'libpng', 'libx11', 'zlib']
Optional-Dependencies	['gdk-pixbuf2']
Build-Dependencies	['gdk-pixbuf2']
Provides	[]
Builddate	05-10-2024 18:14:28
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.1-or-later']
Hash	679634eec53cc8a718d53ba8bf4ee9c39682085137c2337b8ef9eea367578556

# Contributor: Eric Bélanger <eric@archlinux.org>

pkgname=libwmf
pkgver=0.2.13
pkgrel=4
pkgdesc="A library for reading vector images in Microsoft's native Windows Metafile Format (WMF)"
arch=('x86_64')
url="https://github.com/caolanm/libwmf"
license=('LGPL-2.1-or-later')
depends=('expat' 'freetype2' 'glibc' 'libjpeg-turbo' 'libpng' 'libx11' 'zlib')
makedepends=('gdk-pixbuf2')
optdepends=('gdk-pixbuf2: for pixbuf loader')
source=($pkgname-$pkgver.tar.gz::https://github.com/caolanm/libwmf/archive/v$pkgver.tar.gz)
sha256sums=('18ba69febd2f515d98a2352de284a8051896062ac9728d2ead07bc39ea75a068')

prepare() {
  cd ${pkgname}-${pkgver}
  autoreconf -fi
} 

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr \
              --with-gsfontmap=/usr/share/ghostscript/Resource/Init/Fontmap.GS \
              --with-gsfontdir=/usr/share/fonts/gsfonts
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
}