Name	libxcrypt
Description	Modern library for one-way hashing of passwords
Version	4.5.2-1
Package Base	libxcrypt
Homepage	https://github.com/besser82/libxcrypt/
Maintainers	['Christian Hesse <eworm@archlinux.org>', 'Christian Hesse <mail@eworm.de>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libxcrypt
Sources	['https://github.com/besser82/libxcrypt//releases/download/v4.5.2/libxcrypt-4.5.2.tar.xz', 'https://github.com/besser82/libxcrypt//releases/download/v4.5.2/libxcrypt-4.5.2.tar.xz.asc']
Dependencies	['glibc']
Optional-Dependencies	[]
Build-Dependencies	[]
Provides	['libcrypt.so']
Builddate	10-11-2025 22:07:47
Architecture	x86_64
Distro-Version
Licenses	['LGPL']
Hash	7d324b88963786491391468203701efd2c812798a9c3fbcc4ff8a4ddb2d9f276

# Maintainer: Christian Hesse <mail@eworm.de>

pkgbase=libxcrypt
pkgname=(libxcrypt libxcrypt-compat)
pkgver=4.5.2
pkgrel=1
pkgdesc='Modern library for one-way hashing of passwords'
arch=('x86_64')
url='https://github.com/besser82/libxcrypt/'
license=('LGPL')
depends=('glibc')
provides=('libcrypt.so')
install=libxcrypt.install
validpgpkeys=('678CE3FEE430311596DB8C16F52E98007594C21D') # Björn 'besser82' Esser
source=("${url}/releases/download/v${pkgver}/${pkgbase}-${pkgver}.tar.xz"{,.asc})
sha256sums=('71513a31c01a428bccd5367a32fd95f115d6dac50fb5b60c779d5c7942aec071'
            'SKIP')

build() {
  mkdir build-libxcrypt build-libxcrypt-compat

  cd "${srcdir}/build-libxcrypt/"
  "${srcdir}/${pkgbase}-${pkgver}"/configure \
    --prefix=/usr \
    --disable-static \
    --enable-hashes=strong,glibc \
    --enable-obsolete-api=no \
    --disable-failure-tokens
  make
  
  cd "${srcdir}/build-libxcrypt-compat/"
  "${srcdir}/${pkgbase}-${pkgver}"/configure \
    --prefix=/usr \
    --disable-static \
    --enable-hashes=strong,glibc \
    --enable-obsolete-api=glibc \
    --disable-failure-tokens
  make
}

check() {
  cd build-libxcrypt/

  make check 
}

package_libxcrypt() {
  cd build-libxcrypt/

  make DESTDIR="${pkgdir}" install
}

package_libxcrypt-compat() {
  pkgdesc='Modern library for one-way hashing of passwords - legacy API functions'
  depends=('libxcrypt')
  
  cd build-libxcrypt-compat/

  make DESTDIR="${pkgdir}" install

  rm -rf "${pkgdir}"/usr/{include,lib/{lib*.so,pkgconfig},share}
}