Name	libxcvt
Description	library providing a standalone version of the X server implementation of the VESA CVT standard timing modelines generator
Version	0.1.3-1
Package Base	libxcvt
Homepage	https://gitlab.freedesktop.org/xorg/lib/libxcvt
Maintainers	['Andreas Radke <andyrtr@archlinux.org>', 'AndyRTR <andyrtr@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libxcvt
Sources	['https://xorg.freedesktop.org/releases/individual/lib/libxcvt-0.1.3.tar.xz', 'https://xorg.freedesktop.org/releases/individual/lib/libxcvt-0.1.3.tar.xz.sig']
Dependencies	['glibc']
Optional-Dependencies	[]
Build-Dependencies	['meson']
Provides	[]
Builddate	14-12-2024 09:25:45
Architecture	x86_64
Distro-Version
Licenses	['HPND-sell-variant', 'MIT']
Hash	0e402123056ca36d3462ea830d8b18275f8c3d30167b5cda9b8e690f58e53003

# Maintainer: AndyRTR <andyrtr@archlinux.org>

pkgname=libxcvt
pkgver=0.1.3
pkgrel=1
pkgdesc="library providing a standalone version of the X server implementation of the VESA CVT standard timing modelines generator"
arch=('x86_64')
url="https://gitlab.freedesktop.org/xorg/lib/libxcvt"
license=('MIT' 'HPND-sell-variant')
depends=('glibc')
makedepends=('meson')
source=(https://xorg.freedesktop.org/releases/individual/lib/${pkgname}-${pkgver}.tar.xz{,.sig})
sha512sums=('2fecc784375e69b6e8e46608618a5f5a8ad20ecd5229fd093883fe401dd6ea231d8b77c6753756fff01f3040bef2db60a042d40fc349769ef5348e5cd9ed1f28'
            'SKIP')
#validpgpkeys=('3BB639E56F861FA2E86505690FDD682D974CA72A') # "Matt Turner <mattst88@gmail.com>"
# validpgpkeys=('67DC86F2623FC5FD4BB5225D14706DBE1E4B4540') # "Olivier Fourdan <fourdan@xfce.org>"
validpgpkeys=('4A193C06D35E7C670FA4EF0BA2FB9E081F2D130E') # "Alan Coopersmith <alan.coopersmith@oracle.com>"


build() {
  arch-meson ${pkgname}-${pkgver} build
  meson compile -C build
}

check() {
  meson test -C build #--print-errorlogs
}

package() {
  DESTDIR="$pkgdir" meson install -C build
  install -m644 -Dt "${pkgdir}/usr/share/licenses/${pkgname}" "${pkgname}-${pkgver}/COPYING"
}