Name	libxkbcommon-x11
Description	Keyboard handling library using XKB data for X11 XCB clients
Version	1.13.1-1
Package Base	libxkbcommon
Homepage	https://xkbcommon.org/
Maintainers	['Jan Alexander Steffens (heftig) <heftig@archlinux.org>']
Contributors	['Daniel Micay <danielmicay@gmail.com>', 'Mladen Pejakovic <pejakm@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libxkbcommon
Sources	['git+https://github.com/xkbcommon/libxkbcommon#tag=xkbcommon-1.13.1']
Dependencies	['glibc', 'libxcb', 'libxkbcommon', 'libxkbcommon.so']
Optional-Dependencies	[]
Build-Dependencies	['bash-completion', 'doxygen', 'git', 'glibc', 'graphviz', 'libxcb', 'libxml2', 'meson', 'wayland', 'wayland-protocols', 'xkeyboard-config', 'xorgproto']
Provides	['libxkbcommon-x11.so']
Builddate	03-12-2025 17:30:00
Architecture	x86_64
Distro-Version
Licenses	['MIT']
Hash	e7ead32dc32faf3c1ace296f9d3ea11173e665118da6d049a06b73b1de49bb4f

# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Daniel Micay <danielmicay@gmail.com>
# Contributor: Mladen Pejakovic <pejakm@gmail.com>

pkgbase=libxkbcommon
pkgname=(
  libxkbcommon
  libxkbcommon-x11
  libxkbcommon-doc
)
pkgver=1.13.1
pkgrel=1
pkgdesc='Keymap handling library for toolkits and window systems'
url='https://xkbcommon.org/'
arch=(x86_64)
license=(MIT)
makedepends=(
  bash-completion
  doxygen
  git
  glibc
  graphviz
  libxcb
  libxml2
  meson
  wayland
  wayland-protocols
  xkeyboard-config
  xorgproto
)
checkdepends=(
  libgl
  xorg-server-xvfb
)
source=(
  "git+https://github.com/xkbcommon/libxkbcommon#tag=xkbcommon-$pkgver"
)
b2sums=('1d706adccf2fe16b0e9bd2805dd7e798ba6c561f1b02c034c146a76383188a0089ff286d0fbec6083473adb056a60864f30367cbf1fc22e3d378415b1a4665f9')

prepare() {
  cd libxkbcommon
}

build() {
  local meson_options=(
    -D enable-docs=true
  )

  arch-meson libxkbcommon build "${meson_options[@]}"
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

_pick() {
  local p="$1" f d; shift
  for f; do
    d="$srcdir/$p/${f#$pkgdir/}"
    mkdir -p "$(dirname "$d")"
    mv "$f" "$d"
    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  done
}

package_libxkbcommon() {
  depends=(
    glibc
    libxml2
    xkeyboard-config
  )
  optdepends=(
    'libxkbcommon-x11: xkbcli interactive-x11'
    'wayland: xkbcli interactive-wayland'
  )
  provides=(
    libxkbcommon.so
    libxkbregistry.so
  )

  meson install -C build --destdir "$pkgdir"

  _pick x11 "$pkgdir"/usr/lib/*x11*
  _pick x11 "$pkgdir"/usr/lib/pkgconfig/*x11*
  _pick x11 "$pkgdir"/usr/lib/xkbcommon/*x11*
  _pick x11 "$pkgdir"/usr/include/xkbcommon/*x11*
  _pick x11 "$pkgdir"/usr/share/man/man1/*x11*

  _pick doc "$pkgdir"/usr/share/doc

  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 libxkbcommon/LICENSE
}

package_libxkbcommon-x11() {
  pkgdesc='Keyboard handling library using XKB data for X11 XCB clients'
  depends=(
    glibc
    libxcb
    libxkbcommon
    libxkbcommon.so
  )
  provides=(
    libxkbcommon-x11.so
  )

  mv x11/* "$pkgdir"/

  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 libxkbcommon/LICENSE
}

package_libxkbcommon-doc() {
  pkgdesc='API documentation for libxkbcommon'

  mv doc/* "$pkgdir"/

  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 libxkbcommon/LICENSE
}

# vim:set sw=2 sts=-1 et: