Name	libxmlb
Description	Library to help create and query binary XML blobs
Version	0.3.25-1
Package Base	libxmlb
Homepage	https://github.com/hughsie/libxmlb
Maintainers	['Antonio Rojas <arojas@archlinux.org>', 'Bruno Pagani <archange@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/libxmlb
Sources	['https://github.com/hughsie/libxmlb/releases/download/0.3.25/libxmlb-0.3.25.tar.xz', 'https://github.com/hughsie/libxmlb/releases/download/0.3.25/libxmlb-0.3.25.tar.xz.asc']
Dependencies	['gcc-libs', 'glib2', 'glibc', 'libstemmer', 'xz', 'zstd']
Optional-Dependencies	[]
Build-Dependencies	['meson', 'gobject-introspection', 'gtk-doc']
Provides	[]
Builddate	03-02-2026 16:35:35
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.1-only']
Hash	de7836d1909245fd36f2bca9bbcd9d590b543e009c4789e12f4c2ce5e5f36b45

# Maintainer: Bruno Pagani <archange@archlinux.org>

pkgname=libxmlb
pkgver=0.3.25
pkgrel=1
pkgdesc="Library to help create and query binary XML blobs"
arch=(x86_64)
url="https://github.com/hughsie/libxmlb"
license=(LGPL-2.1-only)
depends=(gcc-libs glibc glib2 libstemmer xz zstd)
makedepends=(meson gobject-introspection gtk-doc)
checkdepends=(shared-mime-info)
source=("https://github.com/hughsie/libxmlb/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.xz"{,.asc})
sha256sums=('77f2768c9debd2e946173cdf9465efd987849805e7c58251c5772ea728a61d9a'
            'SKIP')
validpgpkeys=(163EB50119225DB3DF8F49EA17ACBA8DFA970E17) # Richard Hughes <richard@hughsie.com>

build() {
  arch-meson ${pkgname}-${pkgver} build -D stemmer=true
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "${pkgdir}"
  rm -r "${pkgdir}"/usr/{lib,share}/installed-tests/
}