Name	lmdb
Description	Symas Lightning Memory-Mapped Database
Version	0.9.33-1
Package Base	lmdb
Homepage	https://symas.com/lmdb
Maintainers	['Antonio Rojas <arojas@archlinux.org>', 'Felix Yan <felixonmars@archlinux.org>']
Contributors	['Matt Monaco <cx monaco matt>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/lmdb
Sources	['git+https://git.openldap.org/openldap/openldap.git#tag=LMDB_0.9.33', 'lmdb.pc']
Dependencies	['glibc']
Optional-Dependencies	[]
Build-Dependencies	['git']
Provides	[]
Builddate	16-08-2024 15:47:01
Architecture	x86_64
Distro-Version
Licenses	['custom:OpenLDAP']
Hash	307d61635bd36a80e0d2056b968ab7bde045ef3674d2f9518fc53798a9ef2e40

# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Matt Monaco <cx monaco matt>

pkgname=lmdb
pkgver=0.9.33
pkgrel=1
pkgdesc="Symas Lightning Memory-Mapped Database"
arch=('x86_64')
url="https://symas.com/lmdb"
license=('custom:OpenLDAP')
depends=('glibc')
makedepends=('git')
options=('!emptydirs')
source=("git+https://git.openldap.org/openldap/openldap.git#tag=LMDB_$pkgver"
        lmdb.pc)
sha512sums=('dad9b7fa441d02202131e911aa3b6aad09c98c6e972ae69adf2867ccce2065397d868751bf93a4e00b13a3165ffd33bff33f36a062c1a6467a5543367efb381d'
            '0349d4b08a1f93fe338d8f8e3e5a83e24211a46f999fe529bc1ac49c8c4975559d95a548c203d9427e3f82d62e934ba3cd1be6f734f9b9405b2a26477be4ed33')

prepare() {
  sed -e "s|@PKGVER@|$pkgver|" -i lmdb.pc
}

build() {
  cd openldap/libraries/liblmdb
  make CFLAGS="$CFLAGS" CPPFLAGS="$CPPFLAGS" LDFLAGS="$LDFLAGS" prefix=/usr
}

check() {
  cd openldap/libraries/liblmdb
  make test
}

package() {
  cd openldap/libraries/liblmdb
  install -dm755 "$pkgdir"/usr/{bin,lib,include,man/man1,share}
  make DESTDIR="$pkgdir" prefix=/usr install

  mv "$pkgdir"/usr/man "$pkgdir"/usr/share/man

  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
  install -Dm644 "$srcdir"/lmdb.pc -t "$pkgdir"/usr/lib/pkgconfig/
}